1. CLICK HERE TO JOIN WHATSAPP CHANNEL FOR TDL PROGRAMS

Help in my code Totals not comming

Discussion in 'Requests' started by Harikishan, Mar 8, 2018.

    
  1. Harikishan

    Harikishan New Member


    [#Part: VTYP BehaviourMain]
    Option : VTYP BehaveMain OTS VchTypeConfirm : @@IsOTSVchType

    [!Part : VTYP BehaveMain OTSVchTypeConfirm]
    Add : Line : After : VTYP PrintSave :VTYP OTS VchTypeConfirm

    [Line : VTYP OTS VchTypeConfirm]
    Field : Long Prompt, Logical Field
    Local : Field : Long Prompt : Set as : "Print GST Format ?"
    Local : Field : Long Prompt : Width : @@LongWidth
    Local : Field : Logical Field : Storage : OTSVchTypeConfirm1

    [System : Formula]
    IsOTSVchType : $$IsSales:$Parent
    IsOTSNewAllow : $OTSVchTypeConfirm1:VoucherType:$VoucherTypeName

    [System : UDF]
    OTSVchTypeConfirm1 : Logical : 1781

    [#Form : Sales Color]
    Option: OTSSalesOTS Color: @@IsOTSNewAllow

    [!Form:OTSSalesOTS Color]
    Delete : Print
    Add : Print : STC GST INVOICE OTS

    [Report :STC GST INVOICE OTS]
    Use : Printed Invoice
    Delete: Form : Printed Invoice
    Form : STC GST INVOICE OTS

    [Form:STC GST INVOICE OTS]
    Space Left: 0.10 Inch
    Space Bottom: 0.10 Inch
    Space Right: 0.10 Inch
    Space Top:0.50 Inch

    Part: OTS Opening Page Break, OTS Invoice Body
    Bottom Part:OTS GST analisys Bankdetails ledgerentries, OTSInvoiceAmtwordandamount, OTSSingnatureClosingBalanceTerms

    Page Break : ClOTS Page Break, OTS Opening Page Break

    [Part:ClOTS Page Break]
    Lines : GIOTS ClPgBrk

    [Line: GIOTS ClPgBrk]
    Fields : Simple Field
    Local: Field: Simple Field : Set As : "Continued..."
    Local: Field: Simple Field : FullWidth : Yes
    Local: Field: Simple Field : Align : Right
    Border : Full Thin Top


    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    [Style: P9]
    Font: Calibri (Body)
    Height: 9

    [Style:p10]
    Font:Calibri (Body)
    Height:10

    [Style:p9B]
    Use:p9
    Bold: Yes

    [Style:p9Bold]
    Use: P9
    Bold: Yes

    [Style: Parth CMP Name]
    Font: Adobe Garamond Pro Bold
    Height:20
    Bold: Yes

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    [Part: OTS Opening Page Break]
    Part: OTS Invoice Title, OTS CMP Details, OTS Coloumn Titles ;;, OTS Leading Details,
    Vertical: Yes

    [Part:OTS Invoice Title]
    Line:OTS Invoice Title

    [Line:OTS Invoice Title]
    Field: Simple Field
    Right Field:Name Field
    Local: Field: Simple Field: Set as: "TAX INVOICE"
    Local: Field: Simple Field: Style: Large Bold
    Local: Field: Simple Field: Space Left: 60
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Name Field: Set as:If @@GetCopyNum = 1 Then "ORIGINAL FOR RECIPIENT" Else +
    If @@GetCopyNum = 2 Then $$LocaleString:"DUPLICATE FOR TRANSPOTER" Else +
    If @@GetCopyNum = 3 Then $$LocaleString:"TRIPLICATE FOR SUPPLIER " Else +
    If @@GetCopyNum = 4 Then $$LocaleString:"EXTRA COPY" Else $$LocaleString:"EXTRA COPY"

    ;;
    [Part:OTS CMP Details]
    Left Part: OTS CMP Name Details
    Right Part: OTS Leading Details
    Border: Thick Cover
    [Part: OTS CMP Name Details]
    Line: OTS CMP Name, OTS CMP Address, OTS CMP Contact Details

    [Line: OTS CMP Name]
    Field: Name Field
    Local: Field: Name Field: Set as: @@CmpMailName
    Local: Field: Name Field: Style:parth CMP Name
    Local: Field: Name Field: Full Width: Yes

    [Line:OTS CMP Address]
    Field: Name Field
    Local: Field: Name Field: Set as: $$FullList:CompanyAddress:$Address
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style:p9
    Local: Field: Name Field: Line:0

    [Line:OTS CMP Contact Details]
    Field: Medium Prompt, Simple Field, Simple Prompt, Name Field
    Local: Field: Medium Prompt: Set as: "Contact No"
    ;;Local: Field: Medium Prompt: Style: P9B
    ;;Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Set as: $PhoneNumber:Company:##SVCurrentCompany +" / "+ $MobileNumbers:Company:##SVCurrentCompany
    ;;Local: Field: Simple Prompt: Style:p9B
    Local: Field: Simple Field: Set as: "GSTIN No : " +" "+ $CMPGSTIN ;;+" "+" PAN No :"+" "+$IncomeTaxNumber:Ledger:$BasicBuyerName
    Local: Field: Simple Prompt: Set as: "PAN No."
    ;;Local: Field: Simple Prompt: Space Left: 5
    ;;Local: Field: Name Field: Style: P9
    Local: Field: Name Field: Set as: $IncomeTaxNumber:Company:##SVCurrentCompany


    [Part:OTS Leading Details]
    Left Part: OTS Customer Details
    Right Part: OTS Invoice Details
    Border: Thin Left

    [Part:OTS Customer Details]
    Line:OTS Customer Details Title, OTS Customer Name, OTS Customer Address, OTS Customer State Name, OTS Customer GST No, OTS Customer Contact
    Width: 70% Page

    [Line:OTS Customer Details Title]
    Field: Simple Field
    Local: Field: Simple Field : Set as: "Details for Buyer (Billed & Shipped To )"
    Local: Field: Simple Field: Style:p9B
    Local: Field: Simple Field: Full Width: Yes

    [Line:OTS Customer Name]
    Field: Simple Field
    Local: Field: Simple Field: Set as: @@SimpleOtherPartyName
    Local: Field: Simple Field: Style: P9B
    Local: Field: Simple Field: Full Width: Yes
    ;;Space Top:1

    [Line:OTS Customer Address]
    Field: Simple Field
    Local: Field: Simple Field: Set as: $$FullList:BasicBuyerAddress:$BasicBuyerAddress
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Simple Field: Line:0

    [Line:OTS Customer State Name]
    Field: Simple Field
    Local: Field: Simple Field: Set as: "State Name"+" : "+ $StateName +" "+ "Code :"+" "+ $$getgststatecode:mad:StateName
    Local: Field: Simple Field: Local Formula:StateName : If NOT ($$IsEmpty:$StateName OR $$IsSysName:NotApplicable:$StateName) Then $StateName Else $LedStateName:Ledger:mad:PartyName
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Simple Field: Style: P9

    [Line:OTS Customer GST No]
    Field: Simple Field
    Local: Field: Simple Field: Set as: "GSTIN No : " +" "+ $PartyGSTIN +" "+" PAN No :"+" "+$IncomeTaxNumber:Ledger:$BasicBuyerName
    Local: Field: Simple Field: Full Width: Yes
    Local: Field: Simple Field: Style: P9

    [Line:OTS Customer Contact]
    Field: Simple Field
    Local: Field: Simple Field: Set as: "Contact Details :"+" "+ @@VchContactNo
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes

    [Part:OTS Invoice Details]
    Line: OTS Invoice No, OTS Invoice Date, OTS PO No,OTS PO Date, OTS DC No, OTS DC Date
    ;;Width: 20% Page
    Border: Thin Left

    [Line:OTS Invoice No]
    Field: Medium Prompt,Simple Field
    Local: Field: Medium Prompt: Set as: "Invoice No"
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as: $VoucherNumber
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
    ;;Space Top:1

    [Line:OTS Invoice Date]
    Field: Medium Prompt, Simple Field
    Local: Field: Medium Prompt: Set as: "Dated"
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as: $Date
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes
    [Line:OTS PO No]
    Field: Medium Prompt, Simple Field
    Local: Field: Medium Prompt: Set as: "PO No."
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as: $BasicPurchaseOrderNo
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes


    [Line:OTS PO Date]
    Field: Medium Prompt, Simple Field
    Local: Field: Medium Prompt: Set as: "PO Date."
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as: $BasicOrderDate
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes

    [Line:OTS DC No]
    Field: Medium Prompt, Simple Field
    Local: Field: Medium Prompt: Set as: "Delivery Challan No"
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as: $BasicShipDeliveryNote
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes

    [Line:OTS DC Date]
    Field: Medium Prompt, Simple Field
    Local: Field: Medium Prompt: Set as: "Delivery Challan Date"
    Local: Field: Medium Prompt: Style: P9B
    Local: Field: Medium Prompt: Width: 15
    Local: Field: Simple Field: Set as:$BasicShippingDate
    Local: Field: Simple Field: Style: P9
    Local: Field: Simple Field: Full Width: Yes

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    [Part:OTS Coloumn Titles]
    Line:OTS Invoice Body Title,OTS Invoice Body Title1
    Border: Thick Cover
    Common Border: Yes

    [Part: OTS Invoice Body]
    Part:OTS Invoice Body Coloumns
    Vertical: Yes
    Border: Thin Cover

    [Part:OTS Invoice Body Title]
    Line:OTS Invoice Body Title,OTS Invoice Body Title1
    Common Border: Yes

    [Line:OTS Invoice Body Title]
    Use: OTS Invoice Body Coloumns

    Local: Field: Default: Type: String
    Local: Field: Default: Style: P9B
    Local: Field: Default: Align: Center

    Local: Field:OTS SrNo: Set as: "Sr "
    Local: Field:OTS Item Description: Set as: "Item"

    Local: Field:OTS HSN Code: Set as: "HSN "

    Local: Field:OTS Actual Qty: Set as: "Actual"
    Local: Field:OTS Billed Qty: Set as: "Billed"
    Local: Field: OTS Rate: Set as: "Rate"
    Local: Field:OTS Discount: Set as: "Dis"
    Local: Field:OTS Discount2: Set as: "Dis2"
    Local: Field:OTS Gross Amt: Set as: "Gross"
    Local: Field:OTS GST Per: Set as: "GST"
    ;;Local: Field:OTS CGST Rate: Set as: "CGST"
    Local: Field: OTS CGST Amt: Set as: "CGST"
    ;;Local: Field:OTS SGST Rate: Set as: "SGST"
    Local: Field:OTS SGST Amt: Set as: "SGST "
    Local: Field:OTS IGST Rate: Set as: "IGST"
    Local: Field:OTS IGST Amount: Set as: "IGST"
    Local: Field:OTS Item Total: Set as: "Total"

    Border: Thin Top
    Space Top: 0.25

    [Line:OTS Invoice Body Title1]
    Use: OTS Invoice Body Coloumns

    Local: Field: Default: Type: String
    Local: Field: Default: Style: P9B
    Local: Field: Default: Align: Center

    Local: Field:OTS SrNo: Set as: "No"
    Local: Field:OTS Item Description: Set as: "Description"

    Local: Field:OTS HSN Code: Set as: "Code"

    Local: Field:OTS Actual Qty: Set as: "Qty"
    Local: Field:OTS Billed Qty: Set as: "Qty"
    Local: Field: OTS Rate: Set as: ""
    Local: Field:OTS Discount: Set as: "%"
    Local: Field:OTS Discount2: Set as: "%"
    Local: Field:OTS Gross Amt: Set as: "Amount"
    Local: Field:OTS GST Per: Set as: "%"
    ;;Local: Field:OTS CGST Rate: Set as: "%"
    Local: Field: OTS CGST Amt: Set as: "Amt"
    ;;Local: Field:OTS SGST Rate: Set as: "%"
    Local: Field:OTS SGST Amt: Set as: "Amt"
    Local: Field:OTS IGST Rate: Set as: "%"
    Local: Field:OTS IGST Amount: Set as: "Amt"
    Local: Field:OTS Item Total: Set as: ""

    Border: Thin Bottom
    Space Bottom: 0.25

    [Part:OTS Invoice Body Coloumns]
    Line:OTS Invoice Body Coloumns
    Repeat:OTS Invoice Body Coloumns:Inventory Entries
    Scroll: Vertical
    Float: No
    Common Border: Yes

    [Line:OTS Invoice Body Coloumns]
    Left Field: OTS SrNo, OTS Item Description
    ;;Right Field: OTS HSN Code,OTS Actual Qty,OTS Billed Qty, OTS Rate, OTS Discount,OTS Discount2, OTS Gross Amt, OTS GST Per,OTS CGST Rate, OTS CGST Amt, OTS SGST Rate, OTS SGST Amt,OTS IGST Rate, OTS IGST Amount, OTS Item Total
    Right Field: OTS HSN Code,OTS Actual Qty,OTS Billed Qty, OTS Rate, OTS Discount,OTS Discount2, OTS Gross Amt, OTS GST Per, OTS CGST Amt, OTS SGST Amt,OTS IGST Rate, OTS IGST Amount, OTS Item Total
    Space Top: 0.15
    Explode : EI DescExplosion : NOT $$IsEmpty:$StockItemName AND ##PRNWithItemDesc AND NOT $$IsEmpty:$BasicUserDescription
    Local: Field:OTS SrNo: Width: 3

    Local: Field:OTS HSN Code: Width: 7

    Local: Field:OTS Actual Qty: Width: 7
    Local: Field:OTS Billed Qty: Width: 7
    Local: Field: OTS Rate: Width: 7
    Local: Field:OTS Discount: Width: 3
    Local: Field:OTS Discount2: Width: 3
    Local: Field:OTS Gross Amt: Width: 7
    Local: Field:OTS GST Per: Width: 3
    ;;Local: Field:OTS CGST Rate: Width: 3
    Local: Field: OTS CGST Amt: Width: 7
    ;;Local: Field:OTS SGST Rate: Width: 3
    Local: Field:OTS SGST Amt: Width: 7
    Local: Field:OTS IGST Rate: Width:3
    Local: Field:OTS IGST Amount: Width:7
    Local: Field:OTS Item Total: Width: 8

    Local: Field:OTS SrNo: Border: Thin Right
    Local: Field:OTS Part No: Border: Thin Left
    Local: Field:OTS HSN Code: Border: Thin Left
    Local: Field:OTS Actual Qty: Border: Thin Left
    Local: Field:OTS Actual Qty:Border: Thin Left
    Local: Field:OTS Billed Qty: Border: Thin Left
    Local: Field: OTS Rate: Border: Thin Left
    Local: Field:OTS Discount: Border: Thin Left
    Local: Field:OTS Discount2: Border: Thin Left
    Local: Field:OTS Gross Amt: Border: Thin Left
    Local: Field:OTS GST Per: Border: Thin Left
    ;;Local: Field:OTS CGST Rate: Border: Thin Left
    Local: Field: OTS CGST Amt: Border: Thin Left
    ;;Local: Field:OTS SGST Rate: Border: Thin Left
    Local: Field:OTS SGST Amt: Border: Thin Left
    Local: Field:OTS IGST Rate: Border: Thin Left
    Local: Field:OTS IGST Amount: Border: Thin Left
    Local: Field:OTS Item Total: Border: Thin Left



    [Field: OTS Sr NO]
    Use: Simple Field
    Set as: $$Line
    Format: "No Zero"
    Style:p9
    Align: Center

    [Field:OTS Item Description]
    Use: Simple Field
    Set as: if NOT $$IsSysName:$StockItemName then @@InvItemName else ""
    Style: P9
    Full Width: Yes
    ;Line:0



    [Field:OTS HSN Code]
    Use: Simple Field
    Set as: $GSTItemHSNCodeEx
    Style:p9


    [Field:OTS Actual Qty]
    Use: Qty Primary Field
    Set as: $ActualQty
    Style:p9


    [Field:OTS Billed Qty]
    Use: Qty Primary Field
    Set as: $BilledQty
    Style:p9

    [Field:OTS Rate]
    Use: Rate Price Field
    Set as: $Rate
    Style:p9

    [Field:OTS Discount]
    Use: Number Field
    Set as: ""
    Set as: $Discount
    Format : "NoZero,Percentage"
    Style:p9

    [Field:OTS Discount2]
    Use: Number Field
    Set as: ""
    Set as: $EIDisc2
    Format : "NoZero,Percentage"
    Style:p9


    [Field:OTS Gross Amt]
    Use:Amount Forex Field
    Set as: $Amount
    Style:p9

    [Field:OTS GST Per]
    Use: Number Field
    Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx
    Format : "NoZero,Percentage"
    Set Always: Yes
    Style:p9

    ;;[Field:OTS CGST Rate]
    ;;Use: Number Field
    ;;Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx /2
    ;;Format : "NoZero,Percentage"
    ;;Set Always: Yes
    ;;Style:p9
    ;;Invisible: If @@IGST > 0 then yes else no


    [Field:OTS CGST Amt]
    Use: Amount Field
    ;;Set as: $Amount * #OTSCGSTRate / 100
    Set as: $Amount * ($GSTClsfnIGSTRateEx /2) / 100
    Style:p9
    Set Always: Yes
    Invisible: If @@IGST > 0 then yes else no

    ;;[Field:OTS SGST Rate]
    ;;Use: Number Field
    ;;Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx /2
    ;;Format : "NoZero,Percentage"
    ;;Set Always: Yes
    ;;Style:p9
    ;;Invisible: If @@IGST > 0 then yes else no

    [Field:OTS SGST Amt]
    Use: Amount Field
    ;;Set as: $Amount * #OTSSGSTRate / 100
    Set as: $Amount * ($GSTClsfnIGSTRateEx /2) / 100
    Style:p9
    Set Always: Yes
    Invisible: If @@IGST > 0 then yes else no

    [Field:OTS IGST Rate]
    Use: Number Field
    Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx
    Format : "NoZero,Percentage"
    Set Always: Yes
    Style:p9
    Invisible: If @@SGST > 0 then yes else no

    [Field:OTS IGST Amount]
    Use: Amount Field
    Set as: $Amount * #OTSIGSTRate / 100
    Style:p9
    Set Always: Yes
    Invisible: If @@SGST > 0 then Yes else no

    [Field:OTS Item Total]
    Use: Amount Field
    Set as: #OTSGrossAmt + #OTSCGSTAmt + #OTSSGSTAmt
    Set Always: Yes
    Style:p9

    [Line:OTS Invoice Body Coloumns Total]
    Use: OTS Invoice Body Coloumns

    Local: Field: Default: Type: String
    Local: Field: Default: Style: P9B
    Local: Field: Default: Align: Center

    Local: Field:OTS SrNo: Set as: ""
    Local: Field:OTS Item Description: Set as: "TOTAL"
    Local: Field:OTS HSN Code: Set as: ""
    Local: Field:OTS Actual Qty: Set as: ""
    Local: Field:OTS Billed Qty: Set as: ""
    Local: Field: OTS Rate: Set as: ""
    Local: Field:OTS Discount: Set as: ""
    Local: Field:OTS Discount2: Set as: ""
    Local: Field:OTS Gross Amt: Set as: $$CollAmtTotal:InventoryEntries:$Amount
    Local: Field:OTS GST Per: Set as: ""
    ;;Local: Field:OTS CGST Rate: Set as: ""
    Local: Field: OTS CGST Amt: Set as: $$FilterAmtTotal:LedgerEntries:CGST1:$Amount
    ;;Local: Field:OTS SGST Rate: Set as: ""
    Local: Field:OTS SGST Amt: Set as: $$FilterAmtTotal:LedgerEntries:SGST1:$Amount

    Local: Field:OTS Item Total: Set as: $Amount
    Border: Thin Top Bottom
    Space Bottom: 0.25
    Space Top: 0.25

    [System: Formula]
    SGST :$$FilterAmtTotal:LedgerEntries:SGST1:$Amount
    SGST1 :$Name:Ledger:$LedgerName Contains $$LocaleString:"SGST"

    CGST :$$FilterAmtTotal:LedgerEntries:CGST1:$Amount
    CGST1 :$Name:Ledger:$LedgerName Contains $$LocaleString:"CGST"

    IGST :$$FilterAmtTotal:LedgerEntries:IGST1:$Amount
    IGST1 :$Name:Ledger:$LedgerName Contains $$LocaleString:"IGST"

    Round :$$FilterAmtTotal:LedgerEntries:Round1:$Amount
    Round1 :$Name:Ledger:$LedgerName Contains $$LocaleString:"Round"

    [Part:OTS GST analisys Bankdetails ledgerentries]
    Left Part:VCH GST AnalysisDetails
    Right Part: OTSBankDetails, OTSLedgerEnteries
    Border: Thick Cover
    Common Border:Yes


    [#Part:VCH GST AnalysisDetails]
    Delete:Border : Thin Box

    [#Part:VCH GST AnalysisDetails]
    Width:50% Page

    [Part:OTSBankDetails]
    Use:EXPINV BankDetails
    Border: Thick Left

    [#Line: EXPINV BankTitle]

    Fields : Simple Field
    Local : Field : Simple Field : Set as : $$LocaleString:"Company's Bank Details" ;;; To Display Company's Bank Details
    Local : Field : Simple Field : Full Width: Yes
    Local : Field : Simple Field : Style:p9B
    Space Top:0.5
    Space Bottom:0.25

    [#Line: EXPINV BankName]

    Fields : Medium Prompt, EXPINV BankName
    Local : Field : Medium Prompt : Set as : $$LocaleString:"Bank Name :" ;;; To Display Bank Name
    Local : Field : Medium Prompt : Width : 18% Page
    Local : Field : Medium Prompt : Style:p9B
    Local : Field:EXPINV BankName:Style:p9

    [#Line: EXPINV BankAccNo]

    Fields : Medium Prompt, EXPINV BankAccountNo
    Local : Field : Medium Prompt : Set as : $$LocaleString:"A/c No. :" ;;; To Display A/c No.
    Local : Field : Medium Prompt : Width : 18% Page
    Local : Field : Medium Prompt : Style:p9B
    Local : Field:EXPINV BankAccountNo:Style:p9

    [#Line: EXPINV BankBranchInfo]

    Fields : Medium Prompt, EXPINV BankBranchName
    Local : Field : Medium Prompt : Set as : $$LocaleString:"Branch & IFS Code :" ;;; To Display Branch & IFS Code
    Local : Field : Medium Prompt : Width : 18% Page
    Local : Field : Medium Prompt : Style:p9B
    Local : Field:EXPINV BankBranchName:Style:p9



    [Part:OTSLedgerEnteries]
    Line:OTSLedgerEnteries
    Repeat:OTSLedgerEnteries:Ledger Entries
    Border: Thick Left
    Common Border: Yes
    ;Scroll: Vertical
    Float: No


    [Line:OTSLedgerEnteries]
    Field: OTSLedgerName, OTSLedgerPercentage,OTSPercentageSing, OTSLedgerAmount
    Remove if: $LedgerName = $PartyLedgerName

    [Field:OTSLedgerName]
    Set as : if ##SATCSDetails AND @@TaxLedgerHasTCS then $$LocaleString:"TCS : Income Tax" else +
    if NOT $$IsSysName:$LedgerName then $LedgerName else "" ;;; used to print on invoice

    Style:p9B
    Align : Right
    FullWidth : Yes
    AbatementVal: If $$Number:$STXAbatementRate = 0 Then $$String:"0" Else $$String:$STXAbatementRate
    LedNarr : (@@IsSales AND ##SALedgerNarr) OR (@@IsPurchase AND ##PULedgerNarr) AND $$Filtercount:LedgerEntries:LedgerNarrFltr > 0
    Option : LeftAlignField : @@AcctsInvoice
    Width:8.7

    [Field:OTSLedgerPercentage]
    Use : Rate Price Field
    Type : Number
    Align : Right
    Format : "NoZero,Decimals:-1"
    Style:p9
    Set as : if ##SATCSDetails AND @@TaxLedgerHasTCS AND NOT $$IsSysName:$TDSRateName:Ledger:$LedgerName then @@TCSITTaxRate else +
    $BasicRateOfInvoiceTax
    Inactive : $$IsSysName:$LedgerName
    Invisible : NOT @@InvWithRate
    Border: Thick Left
    Width: 4

    [Field:OTSPercentageSing]
    Set as:if $$IsEmpty:$BasicRateOfInvoiceTax then "" else "%"
    Set By Condition : @@TaxLedgerHasTCS AND NOT ($$IsSysName:$TDSRateName:Ledger:$LedgerName) : If $$IsEmpty:mad:@TCSITTaxRate Then "" Else "%"
    Inactive : $$IsSysName:$LedgerName
    Invisible : NOT @@InvWithRate
    Width: 2
    Style:p9

    [Field:OTSLedgerAmount]
    Use : Amount Forex Field
    Set as : $$SignedAmount:$Amount:mad:@VchOpposite
    Border: Thick Left
    Align: Right
    Width: 8
    Style:p9

    [Part:OTSInvoiceAmtwordandamount]
    Left Part: OTSAmountinWord
    Right Part:OTSInvoiceAmount
    Border: Thick Cover
    Common Border: Yes

    [Part:OTSAmountinWord]
    Line:OTSAmountinWord

    [Line:OTSAmountinWord]
    Field: Medium Prompt, Name Field
    Local: Field: Medium Prompt: Set as: "Amount In Words"
    Local: Field: Medium Prompt:Style:p9B
    Local: Field: Name Field: Set as:$$InWords:$Amount +" "+ "Only."
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Line:0
    Local: Field: Name Field:Style:p9
    Space Top:0.25
    Space Bottom:0.25

    [Part:OTSInvoiceAmount]
    Line:OTSInvoiceAmount

    [Line:OTSInvoiceAmount]
    Field: Name Field, Amount Field
    Local: Field: Name Field: Set as: "Invoice Total"
    Local: Field: Name Field: Border: Thick Left
    Local: Field: Name Field: Width:26.5
    Local: Field: Name Field: Align: Right
    Local: Field: Name Field: Style:p9B
    Local: Field: Amount Field: Set as: $Amount
    Local: Field: Amount Field: Width:8
    Local: Field: Amount Field: Border: Thick Left
    Local: Field: Amount Field: Style:p9B
    Space Top:0.25
    Space Bottom:0.25

    [Part:OTSSingnatureClosingBalanceTerms]
    Left Part: OTSTermsandClosing
    Right Part: OTSCustomer Signature, OTSSignature
    Border:Thick Box

    [Part:OTSTermsandClosing]
    Part: OTSTermsPart, OTSClosing
    Vertical:Yes
    Width:50% Page

    [Part:OTSTermsPart]
    Line:OTSTermsPart
    Border: Thick Bottom

    [Line:OTSTermsPart]
    Field: Name Field
    Local: Field: Name Field:Set as: "GOODS ONCE SOLD WILL NOT BE TAKEN BACK OR EXCHANGED"
    Local: Field: Name Field: Style: P9B
    Local: Field: Name Field: Align: Center
    Local: Field: Name Field: Full Width: Yes

    [Part:OTSClosing]
    Line: OTSOutStandingDetailsTitle, OTSPreviuosOutstandingBalance, OTSCurrentInvoice, OTSTotalOutStanding

    [Line:OTSOutStandingDetailsTitle]
    Field:Name Field
    Local: Field: Name Field: Set as: "Outstanding Details"
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style:p9B
    Space Top:0.5

    [Line:OTSPreviuosOutstandingBalance]
    Field: Medium Prompt, Amount Field
    Local: Field: Medium Prompt: Set as:"Previous Outstanding"
    Local: Field: Medium Prompt: Style:p9B
    Local: Field: Amount Field: Set as:$$ToValue:($date-1):$ClosingBalance:Ledger:$$CollectionField:$LedgerName:1:LedgerEntries
    Local: Field: Amount Field:Style:p9

    [Line:OTSCurrentInvoice]
    Field: Medium Prompt, Amount Field
    Local: Field: Medium Prompt: Set as:"Current Invoice"
    Local: Field: Medium Prompt: Style:p9B
    Local: Field: Amount Field: Set as:$Amount
    Local: Field: Amount Field:Style:p9

    [Line:OTSTotalOutStanding]
    Field: Medium Prompt, Amount Field
    Local: Field: Medium Prompt: Set as:"Total Outstanding"
    Local: Field: Medium Prompt: Style:p9B
    Local: Field: Amount Field: Set as:$$ToValue:$date:$ClosingBalance:Ledger:$$CollectionField:$LedgerName:1:LedgerEntries
    Local: Field: Amount Field:Style:p9

    [Part:OTSCustomer Signature]
    Line: For OTSCustomer Signature, OTSAcceptance
    Border: Thick Left

    [Line:For OTSCustomer Signature]
    Field: Name Field
    Local: Field: Name Field: Set as: "For" +" "+ @@SimpleOtherPartyName
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9B
    Local: Field: Name Field: Align: Center
    Space Top:0.5

    [Line:OTSAcceptance]
    Field: Name Field
    Local: Field: Name Field: Set as: "I received goods in good condition and I have read the terms & condition. I agree with it."
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9
    Local: Field: Name Field: Line:0
    Space Top:3


    [Part:OTSSignature]
    Line: ForOTSSignature, OTSAuthorised
    Border: Thick Left
    Width:36.5

    [Line:ForOTSSignature]
    Field: Name Field
    Local: Field: Name Field: Set as: "For" +" "+ @@CmpMailName
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9B
    Local: Field: Name Field: Align: Center
    Space Top:0.5

    [Line:OTSAuthorised]
    Field: Name Field
    Local: Field: Name Field: Set as: "Proprietor/Manager"
    Local: Field: Name Field: Full Width: Yes
    Local: Field: Name Field: Style: P9B
    Local: Field: Name Field: Align: Center
    Space Top:3
     
    Harikishan, Mar 8, 2018
    #1


  2. Rakesh Patel

    Rakesh Patel New Member


    not working
     
    Rakesh Patel, May 16, 2018
    #2


  3. Rakesh Patel

    Rakesh Patel New Member


    Add this line
    Bottom Line: OTS Invoice Body Coloumns Total
    in
    [Part:OTS Invoice Body Coloumns]
    Check it.....
     
    Rakesh Patel, May 26, 2018
    #3


  4. Rakesh Patel

    Rakesh Patel New Member


    Add this line
    Bottom Line: OTS Invoice Body Coloumns Total
    in
    [Part:OTS Invoice Body Coloumns]
    Check it.....
     
    Rakesh Patel, May 26, 2018
    #4


  5. Rakesh Patel

    Rakesh Patel New Member


    Add this line
    Bottom Line: OTS Invoice Body Coloumns Total
    in
    [Part:OTS Invoice Body Coloumns]
    Check it.....
     
    Rakesh Patel, May 26, 2018
    #5


  6. Rakesh Patel

    Rakesh Patel New Member


    Add this line
    Bottom Line: OTS Invoice Body Coloumns Total
    in
    [Part:OTS Invoice Body Coloumns]
    Check it.....
     
    Rakesh Patel, May 26, 2018
    #6


Share This Page