GSTIN Search, HSN Search, GST Return Status

->Load the below TDL Code
-> In Ledger Form there will be two buttons for 1)Verify GTSIN 2) Return Status
-> Verify GSTIN Button will open the browser with GSTIN Info of the current party
-> Return Status Button will ask for the year of Filing then open the browser with the result of the returns
-> Year format should be (YYYY-YY) (2020-21)
->In Stock Item->GST Details Form there will be a button Verify HSN, it will open the details of current HSN in the browser

Code:

[#Form:Ledger]
    Add:Buttons:VerifyGST,ReturnStatus
   
[#Form: GST Classification Details]
    Add:Button:VerifyHSN
   
[Button:VerifyGST]
    Title:"Verify GSTIN"
    Key:ALT+V
    Action:Call:VerifyGSTIN
   
[Button:ReturnStatus]
    Title:"Return Status"
    Key:ALT+R
    Action:Call:ReturnStatus
   
[Button:VerifyHSN]
    Title:"Verify HSN"
    Key:ALT+H
    Action:Call:VerifyHSN
   
[Function:ValidateGST]
    01:If:$$IsEmpty:#LedGSTIN or $$StringLength:#LedGSTIN < 15
    02:Msg Box:"Info":"Invalid GSTIN"
    03:Return:False
    04:End If
    05:Return:True
   
[Function:VerifyGSTIN]
    01:If:$$ValidateGST
    02:Browse Url:@@GetGSTINURL
    03:End If
   
[Function:ReturnStatus]
    01:If:$$ValidateGST
    02:Alter:ReturnStatus
    03:End If
   
[Function:VerifyHSN]
    01:If:$$IsEmpty:##vGSTMstCode
    02:Msg Box:"Info":"Invalid HSN CODE"
    03:Return
    04:End If
    05:Browse Url:@@GetHSNURL
   
[Report:ReturnStatus]
    Title:"Return Status"
    Form:ReturnStatus
   
[Form:ReturnStatus]
    Part:ReturnStatus
    Height:50% page
    Width:50% page
    On:Form Accept:Yes:Browse Url :@@GetGSTRTNURL
   
[Part:ReturnStatus]
    Space Bottom:2
    Space Left:2
    Space Right:2
    Space Right:2
    Lines:ReturnSt1,ReturnSt2,ReturnSt3
    Bottom Line:ReturnSt4
   
[Line:ReturnSt1]
    Field:NameField
    Local:Field:NameField:Info:"Return Filing Status"
    Local:Field:NameField:Full Width:Yes
    Local:Field:NameField:Align:Center
    Local:Field:NameField:Border:ThinBottom
   
[Line:ReturnSt2]
    Space Top:4
    Field:MediumPrompt,NameField
    Local:Field:MediumPrompt:Info:"Party GSTIN"
    Local:Field:NameField:Set as:#LedGSTIN
    Local:Field:NameField:Read Only:Yes
    Local:Field:NameField:Width:40
   
[Line:ReturnSt3]
    Space Top:2
    Field:MediumPrompt,ReturnStYear
    Local:Field:MediumPrompt:Info:"Enter Year (YYYY - YY)"
    
   
[Field:ReturnStYear]
    Use:NameField
    Width:40
    Control:IsInvalidYear:$$IsEmpty:$$Value
    Set as:$$String:@@Getfilingfrom+ "-"+$$String:@@Getfilingend
   
[Line:ReturnSt4]
    Field:NameField
    Local:Field:NameField:Info:"*Year should in the format -  YYYY-YY"
    Local:Field:NameField:Full Width:Yes
    Local:Field:NameField:Align:Center
    Local:Field:NameField:Color:Red
   

[System:Formulas]
    GetGSTINURL:"https://www.mastersindia.co/gst-number-search-and-gstin-verification/?postTokenId=16127795626021102a0cd56&keyword="+#LedGSTIN
    GetGSTRTNURL:"https://www.mastersindia.co/check-gst-return-status/?postTokenId=161277872560210ce584524&financial_year="+#ReturnStYear+"&keyword="+#LedGSTIN
    GetHSNURL:"https://www.mastersindia.co/gst/hsn-code-search/?postTokenId=161278374960212085f2129&keyword="+##vGSTMstCode
    IsInvalidYear:"Invalid year range"
    Getfilingfrom :$$YearOfDate:($StartingFrom:Company:##SvCurrentCompany)
    Getfilingto:$$StringPart:@@Getfilingfrom:2:2
    Getfilingend:($$Number:@@Getfilingto) + 1

 

PERFECT

 

Works Perfectly,

Is this website shows real-time update. ?

i.e. data is as updated as on gst.gov.in ?

 

Yes
they are GSP's so they have access to GST data.
and they also provide API which you integrate directly into tally.
but they are paid API.

 

little Change for Company with multiple Financial years

Getfilingfrom :$$YearOfDate$$FinYearBeg:##SVCurrentDate:$StartingFrom:Company:##SVCurrentCompany)