PARTY WISE BROKER REPORT TDL

Hello Friends , we are posting codes of the above tdl and facing a peculiar issue in the code. When we are trying to run the code in tally erp9 6.6.2 in one license of the tally its working fine but when we try to run the same code in another license of the tally.erp9 6.6.2 , the BrokerWise F5 button is in inactive mode. we could not find the issue , please help.

;===============================================================
;======================= F11 Feature ===========================
;===============================================================

[#Part: CMP AccFeat Left]
Add : Line : At End : CMP EnableBrokerLine

[Line:CMP EnableBrokerLine]
Space Bottom : 1.5 mms
Field : Long Prompt,CMP EnableBrokerLine
Local : Field : Long Prompt : Set as : "Enable Broker wise Report.?:"

[Field:CMP EnableBrokerLine]
Use : Logical Field
Storage : EnableBroker
Set as : If $$IsEmpty:$$Value then "No" else $$Value
Sub Form: CMP BrokerNameReport: $$Value = "Yes"

[Report: CMP BrokerNameReport]
Form : CMP BrokerNameForm
Object : Company

[Form: CMP BrokerNameForm]
Part : CMPBrokerDetails
Background : White, Petal Pink

[Field:CMPName Field]
Use : Name Field
Skip : Yes
Align : Center
Border : Thin Bottom

[Part:CMPBrokerDetails]
Part : CMP BrokerNamePart,CMP TransportPart,CMP LoadManPart
Vertical : No
Common Border : Yes

[Part: CMP BrokerNamePart]
Line : CMP BrokerNamePartTit,CMP BrokerName LineDetails
Repeat : CMP BrokerName LineDetails: BrokerNameList
BreakOn : $$IsEmpty:$BrokerNameList
Height : 10
Scroll : Vertical
CommonBorder: Yes
Space Left : 2 mms
Space Right : 2 mms
Border : Thin Right

[Line:CMP BrokerNamePartTit]
Field : CMPName Field
Local : Field : CMPName Field : Set as : "Boker Name"

[Line: CMP BrokerName LineDetails]
Field : CMP BrokerNameList;,CMP TransportList,CMP LoadmanList;,CMP Broker CommissionField

[Field: CMP BrokerNameList]
Use : Name Field
Storage : BrokerNameList
Style : Small Bold

[Part:CMP TransportPart]
Line : CMP TransportPartTit,CMP TransportPart
Repeat : CMP TransportPart: TransportList
BreakOn : $$IsEmpty:$TransportList
Height : 10
Scroll : Vertical
CommonBorder: Yes
Space Left : 2 mms
Space Right : 2 mms
Border : Thin Right

[Line:CMP TransportPartTit]
Field : CMPName Field
Local : Field : CMPName Field : Set as : "Transport Name"

[Line:CMP TransportPart]
Field : CMP TransportList

[Field: CMP TransportList]
Use : Name Field
Storage : TransportList
Style : Small Bold

[Part:CMP LoadManPart]
Line : CMP LoadmanListTit,CMP LoadmanList
Repeat : CMP LoadmanList: LoadmanList
BreakOn : $$IsEmpty:$LoadmanList
Height : 15
Scroll : Vertical
CommonBorder: Yes
Space Left : 2 mms
Space Right : 2 mms

[Line:CMP LoadmanListTit]
Field : CMPName Field
Local : Field : CMPName Field : Set as : "Loadman Name"

[Line:CMP LoadmanList]
Field : CMP LoadmanList

[Field: CMP LoadmanList]
Use : Name Field
Storage : LoadmanList
Style : Small Bold

;===============================================================
;======================= Add Fields ===========================
;===============================================================

[#PartBLLINE Narration]
Add : Line : Before : VCH NarrPrompt : VCHBrokerLine

[Line:VCHBrokerLine]
Invisible : NOT $EnableBroker:Company:##SVCurrentCompany OR NOT $$IsSales:##SVVoucherType
Field : VCHBrokerNameTit,VCHBrokerName,VCHTransportTit,VCHTransport,VCHLoadManTit,VCHLoadMan

[Field:VCHBrokerNameTit]
Use : Meduim Prompt
Set as : "Broker Name :"
Skip : Yes

[Field:VCHTransportTit]
Use : VCHBrokerNameTit
Set as : "Transport Name :"

[Field:VCHLoadManTit]
Use : VCHBrokerNameTit
Set as : "Loadman Name :"

[Field:VCHBrokerName]
Use : Name Field
Storage : BrokerName
Table : BrokerNameColl,EndofList
Show Table : Always
Key : CreateBroker

[Field:VCHTransport]
Use : Name Field
Storage : TransportName
Table : TransportNameColl,EndofList
Show Table : Always
Key : CreateBroker

[Field:VCHLoadMan]
Use : Name Field
Storage : LoadmanName
Table : LoadmanNameColl,EndofList
Show Table : Always
Key : CreateBroker

[Key:CreateBroker]
Key : Alt + C
Action : Alter : CMP BrokerNameReport

;;=========================================================
;;================= Broker wise Report ==================
;;=========================================================
[#Menu: Gateway of Tally]
Add : Key Item : After : @@locSalesRegister : "Party-wise Sales" : R : Display : BrokerReport
;Control : BrokerReport : $EnableBroker:Company:##SVCurrentCompany

[Report:BrokerReport]
Use : DSP Template
Title : "Broker Report"
Variable: SVFromDate, SVToDate
Repeat : PARTYNAME1
Form : BrokerReport
Set : SVFromDate : $$MonthStart:##SVCurrentDate
Set : SVToDate : $$MonthEnd:##SVCurrentDate
Set : FilterBroker : ""
Set : FilterTransport : ""
Set : FilterLoadman : ""

[Form:BrokerReport]
Button : PrintButton, ExportButton
Button : ExplodeFlag,ChangePeriod,BtnBroker
Bottom Toolbar Buttons : EnterToEdit, BottomToolBarBtn8,BottomToolBarBtn9,BottomToolBarBtn10
Part : BWRTitle,BWRPeriod,BWRFilter,BWRDetails
Bottom Part :BWRTotals
Width : 95% Page
Space Left : 2 mms
Space Right : 2 mms

[Key: EnterToEdit]
Key : Enter
Title : $$LocaleString:"Explode"
Type : BottomToolBarBtn2
Action : Explode

[Part:BWRTitle]
Line : BWRTitle
Horizontal Align : Center

[Part:BWRPeriod]
Line : BWRPeriod

[Line:BWRTitle]
Field : Simple Field
Local : Field : Simple Field : Style : Large Bold
Local : Field : Simple Field : Info : "Party-wise Sales"
Local : Field : Simple Field : Border: Thin Bottom
Local : Field : Simple Field : Align : Center

[Line:BWRPeriod]
Right Field : Name Field
Left Field : Short Prompt,RPTBrokerFilter
Local : Field : Name Field : Info : @@DSPDateStr
Local : Field : Name Field : Width : 50
Local : Field : Name Field : Align : Right
Local : Field : Short Prompt : Set as: "Broker:"
Local : Field : Short Prompt : Inactive: Not $EnableBroker:Company:##SVCurrentCompany

[Part:BWRFilter]
Line : BWRTranFilter,BWRLMFilter
Invisible : Not $EnableBroker:Company:##SVCurrentCompany

[Line:BWRTranFilter]
Field : Short Prompt,RPTTransportFilter
Space Top : 1 mms
Local : Field : Default : Use : Simple Field
Local : Field : Short Prompt : Set as : "Transport:"

[Line:BWRLMFilter]
Field : Short Prompt,RPTLoadManFilter
Space Top : 1 mms
Local : Field : Default : Use : Simple Field
Local : Field : Short Prompt : Set as : "Loadman:"

[Field:RPTBrokerFilter]
Inactive : Not $EnableBroker:Company:##SVCurrentCompany
Use : Simple Field
Style : Normal Bold
Set as : @VCHBrokerName
Set Always : Yes
VCHBrokerName : If $$IsEndOfList:##FilterBroker or ##FilterBroker="" Then "Show All" Else ##FilterBroker

[Field:RPTTransportFilter]
Use : RPTBrokerFilter
Set as : @VCHTransport
VCHTransport : if ##FilterTransport="" or $$IsEndOfList:##FilterTransport Then "Show All" Else ##FilterTransport

[Field:RPTLoadManFilter]
Use : RPTBrokerFilter
Set as : @VCHLoadMan
VCHLoadMan : if ##FilterLoadman="" or $$IsEndOfList:##FilterLoadman Then "Show All" Else ##FilterLoadman


[Line:BWRHead]
Use : BWRDetails
Border : Column Titles
Local : Field : Default : Type : String
Local : Field : Default : Align : Center
Local : Field : Default : Border : Thin Left
Local : Field : Default : Style : Normal Bold
Local : Field : SWSno : Set as : "Sno"
Local : Field : SWSno : Border : Thin Left Right
Local : Field : BWRPARTYNAME1 : Set as : "Party Name"
Local : Field : BWRPARTYNAME1 : Align : Center
Local : Field : BWRPARTYVATNo : Set as : "VAT No"
Local : Field : BWRPARTYVATNo : Align : Center
Local : Field : BWRPARTYGSTNo : Set as : "GST No"
Local : Field : BWRPARTYGSTNo : Align : Center
Local : Field : BWRActulQty : Set as : "Actual Qty"
Local : Field : BWRActulQty : Align : Center
Local : Field : BWRBilledQty : Set as : "Billed Qty"
Local : Field : BWRBilledQty : Align : Center
Local : Field : BWRAmount : Set as : "Amount"
Local : Field : BWRAmount : Border : Thin Left Right
Space Top : 1.5 mms
Space Bottom: 1.5 mms

[Part:BWRDetails]
Line : BWRHead,BWRDetails
Repeat : BWRDetails:BWRPartyWise
Scroll : Vertical
Total : BWRActulQty,BWRBilledQty,BWRAmount
Common Border : Yes

[Line:BWRDetails]
Field : SWSno,BWRPARTYNAME1,BWRPARTYVATNo,BWRPARTYGSTNo
Right Field : BWRActulQty,BWRBilledQty,BWRAmount
Option : AlterOnEnter : $$IsVoucher
Space Bottom: 0.5 mms
Space Top : 0.5 mms
Border : Thin Top
Explode : BWRExplode : ($$KeyExplode OR ##ExplodeFlag)

[Field:BWRDefault]
Use : Name Field
Style : Normal Bold

[Field:SWSno]
Use : BWRDefault
Set as : $$Line
Width : 1.5 cm
Align : Center
Border : Thin Left Right

[Field:BWRPARTYNAME1]
Use : BWRDefault
Set as : $PARTYNAME1
Width : 60
Quick Search: Yes
Space Left : 2 mms

[Field:BWRPARTYVATNo]
Use : BWRDefault
Set as : $VATTinNumber ;;"VAT No"
Width : 12
Quick Search: Yes
Space Left : 2 mms

[Field:BWRPARTYGSTNo]
Use : BWRDefault
Set as : $PartyGSTIn ;;"GST No"
Width : 15
Quick Search: Yes
Space Left : 2 mms

[Field:BWRActulQty]
Use : Qty Field
Type : Number
Set as : $TotActQty;VoucherTypeName
Width : 16
Space Left : 2 mms
Border : Thin Left Right

[Field:BWRBilledQty]
Use : BWRActulQty
Set as : $TotBillQty
Width : 16
Space Left : 2 mms
Border : Thin Right

[Field:BWRAmount]
Use : BWRDefault
Set as : $TotAmount
Type : Amount
Width : @@AmountWidth
Format : "No Zero, Symbol," + ##ShowForex
Align : Right
Key : Calculator
Max : @@MaxNumberWidth
Width : 16
Space Right : 2 mms
Border : Thin Right
Tooltip : "Amount Without TAX"

[Part:BWRTotals]
Line : BWRTotal

[Line:BWRTotal]
Border : Totals
Use : BWRDetails
Local : Field : Default : Type : String
Local : Field : Default : Align : Right
Local : Field : Default : Style : Large Bold
Local : Field : Default : Border : Thin Left
Local : Field : SWSno : Set as : ""
Local : Field : BWRPARTYNAME1 : Set as : "Grand Total"
Local : Field : BWRPARTYVATNo : Set as : ""
Local : Field : BWRPARTYGSTNo : Set as : ""
Local : Field : BWRActulQty : Set as : $$Total:BWRActulQty
Local : Field : BWRBilledQty : Set as : $$Total:BWRBilledQty
Local : Field : BWRAmount : Set as : $$Total:BWRAmount
Local : Field : BWRAmount : Border : Thin Left Right
Local : Field : BWRAmount : Align : Right

[Part:BWRExplode]
Line : BWRExplode
Repeat : BWRExplode:BWRPartyExplode
Border : Thin Bottom

[Line:BWRExplode]
Use : BWRDetails
Delete : Border
Local : Field : SWSno : Set as : ""
Local : Field : Default : Style : Normal Italic
Local : Field : BWRPARTYNAME1 : Set as : $ItemName
Local : Field : BWRPARTYNAME1 : Align : Right
Local : Field : BWRPARTYVATNo : Set as : "TAX Rate"
Local : Field : BWRPARTYVATNo : Align : Right
Local : Field : BWRPARTYGSTNo : Set as : "HSN Code"
Local : Field : BWRPARTYGSTNo : Align : Right
Local : Field : BWRActulQty : Type : Quantity
Local : Field : BWRActulQty : Set as : $SubActQty
Local : Field : BWRBilledQty : Type : Quantity
Local : Field : BWRBilledQty : Set as : $SubBillQty
Local : Field : BWRAmount : Set as : $SubAmount

;===============================================================
;======================= Add Filters ===========================
;===============================================================

[Button:BtnBroker]
Key : F5
Action : Execute : BrokerReportWise
Title : Broker Wise
Inactive: Not $EnableBroker:Company:##SVCurrentCompany

[Report:BrokerReportWise]
Form : BrokerReportWise

[Form:BrokerReportWise]
Part : BrokerReportWise
Space Left : 2 mms
Space Right : 2 mms

[Part:BrokerReportWise]
Line : BrokerReportWise,FilterTransport,FilterLoadman

[Line:BrokerReportWise]
Field : Medium Prompt,BrokerReportWise
Local : Field : Medium Prompt : Set as : "Select Broker Name:"
Space Bottom : 2 mms

[Field:BrokerReportWise]
Table : BrokerNameColl,EndOfList
ShowTable : Always
Use : Name Field
Width : 20
Border : Thin Box
Variable : FilterBroker
Modifies : FilterBroker

[Line:FilterTransport]
Field : Medium Prompt,FilterTransport
Local : Field : Medium Prompt : Set as : "Select Transport Name:"
Space Bottom : 2 mms

[Field:FilterTransport]
Table : TransportNameColl,EndOfList
ShowTable : Always
Use : Name Field
Width : 20
Border : Thin Box
Variable : FilterTransport
Modifies : FilterTransport

[Line:FilterLoadman]
Field : Medium Prompt,FilterLoadman
Local : Field : Medium Prompt : Set as : "Select Loadman Name:"
Space Bottom : 2 mms

[Field:FilterLoadman]
Table : LoadmanNameColl,EndOfList
ShowTable : Always
Use : Name Field
Width : 20
Border : Thin Box
Variable : FilterLoadman
Modifies : FilterLoadman

;=============================================================
;================= System Functions =========================
;=============================================================

[System:UDF]
EnableBroker : Logical : 4566
BrokerNameList : String : 4567
TransportList : String : 4568
LoadmanList : String : 4569
BrokerName : String : 4570
TransportName : String : 4571
LoadmanName : String : 4572

[System:Formula]
BWRFilter : $BrokerName=@@BrokerWise AND $TransportName=@@TransportWise AND $LoadmanName=@@LoadmanWise
BrokerWise : If $$IsEndOfList:##FilterBroker or ##FilterBroker="" Then $BrokerName Else ##FilterBroker
TransportWise : If $$IsEndOfList:##FilterTransport or ##FilterTransport="" Then $TransportName Else ##FilterTransport
LoadmanWise : If $$IsEndOfList:##FilterLoadman or ##FilterLoadman="" Then $LoadmanName Else ##FilterLoadman
BWRExplodeFilter: $PARTYNAME1=#BWRPARTYNAME1

[Collection: BWR Voucher]
Type : Vouchers : VoucherType
Child of : $$VchTypeSales
Belongs to : Yes
Fetch : Date,VoucherTypeName,PartyLedgerName,BasicPurchaseOrderNo,Amount,BrokerName,TransportName,LoadmanName
Fetch : Ledger:VATTinNumber,LedgerartyGSTIN
Filter : BWRFilter,;Sales ;NotIsoptional Voucher

[Collection:BWRPartyWise]
Source Collection : BWR Voucher
Walk : Inventory Entries
By : PARTYNAME1 : $PartyLedgerName
Aggr Compute: TotActQty : Sum : $ActualQty
Aggr Compute: TotBillQty: Sum : $BilledQty
Aggr Compute: TotAmount : Sum : $Amount
Sort : Default : $PARTYNAME1

[Collection:BWRPartyExplode]
Source Collection : BWR Voucher
Walk : Inventory Entries
By : PARTYNAME1 : $PartyLedgerName
By : ItemName : $StockItemName
Aggr Compute: SubActQty : Sum : $ActualQty
Aggr Compute: SubBillQty: Sum : $BilledQty
Aggr Compute: SubAmount : Sum : $Amount
Filter : BWRExplodeFilter

[Collection:BrokerNameColl]
Type : BrokerNameList: Company
Childof : ##SVCurrentCompany
Format : $BrokerNameList,25
Title : List of Brokers

[Collection:TransportNameColl]
Type : TransportList: Company
Childof : ##SVCurrentCompany
Format : $TransportList,25
Title : List of Transports

[Collection:LoadmanNameColl]
Type : LoadmanList: Company
Childof : ##SVCurrentCompany
Format : $LoadmanList,25
Title : List of Loadmans

[Variable: PARTYNAME1]
Type : String
Repeat : ##DSPRepeatCollection

[Variable:FilterBroker]
Type : String

[Variable:FilterTransport]
Type : String

[Variable:FilterLoadman]
Type : String

[System:Variables]
FilterBroker : ""
FilterTransport : ""
FilterLoadman : ""

 

No reason except.....
Inactive: Not $EnableBroker:Company:##SVCurrentCompany

Just see F11 > F1 enable broker is On

Regards

 

THE MODULE WAS WORKING FINE BUT SINCE FEW DAYS THE BROKER BUTTON HAS BECOME INACTIVE,WHEREAS SAME CODES ARE RUNNING PERFECTLY IN OTHER TALLY .

 

THANK YOU SIR, PROBLEM SOLVED , ABOVE ISSUE WAS THERE ,RECTIFIED IT.

 

There is another issue which is being encountered with the above code is that when we try to run the code in two different licenses it works perfectly fine but when tally is connected via tally.net and other user tries to access from the different location F5 broker button is in inactive mode. . for example suppose there is tally in location A and tally in location B , they both have the above tdl installed and the tdl works perfectly fine in each but when i connect company via tally.net services at location A tally and try to access the company by a user loging in tally in location B the F5 button is inactive in tally at location B. please advice.

 

sir,
how to use the same in Tally prime?

 

By Correcting first line of the code. and 1 Field name charge.

(Sorry for sort answer. I have done these two correction and code working fine in TallyPrime. Just try yourself to solve errors shown in TallyPrime TDS Attachment Screen)

 

Ihave tried but the TDL File is not getting access through it
please help sir.
tally Prime user
For Reference I have attached an image also.

 

Refer Default TDL Reference 1.0.0 and the find the changes in the Prime code

 

Reference from???

 

In which version of tally you are getting error, find the part ([#Part: CMP AccFeat Left]) which you are modifying, does it exists ? in that version of Default TDL. Hope I am clear................

 

Remove this line:
[#Part: CMP AccFeat Left]
Add : Line : At End : CMP EnableBrokerLine

Use this :
[#Part: Company F11 Acc Features]
Local : Part : Cfg PartContent : Add : Lines : CMP Use Type, CMP BillwiseOn, CMP CCOn, CMP Interest, CMP EnableBrokerLine

go to Company, F11 Features you can enable from there in Accounting.

 

Can we know the changes specifically of what??
Please help to change the field name charge
I Can't get it....
Thanks and Regards
Vishal Sancheti
Mumbai.

 

I have done this but the error Show that this tdl is not supported for TALLY PRIME 1.0 RELEASE.
And other field name we need to change for the button to Show enable button on the F11 button?
Please guide me for the same.
Thanks and Regards.

 

Regarding the Codes I have made the changes till now.
but the issue is the activation of the TDL

 

After Changing the Company Field Name
THIS ERROR T0009 is coming

Can Someone Please help me with the codes given below....

thanks & regards.

 

It would be of great help if you share the code in total as non of the changes are working .

 

any solution for the problem you shared, if yes do let me knw.

 

Hello
How can we add a filter to filter the amount field in this report using a button.
please guide.
Thanks in advance

 

sir..... any solution this problem

 

sir..... any solution this problem