Partywise Sales Report

Discussion in 'Free Source Codes' started by sivam, May 30, 2014.

    
  1. sauravjain

    sauravjain Member


    cud not understand by this??/
    plz provide the solution for the error faced in tally erp 9 v 6.2 duplicate description error with variable PartyName even though there are no TDL loaded.
     


  2. Bipin Damania

    Bipin Damania Active Member


    I tried to add column VAT Tin Number & GST Number and also GST Tax Rate and GST HSN Code with Item Name but not getting the same please check & reply.
     

    Attached Files:

    Last edited: Dec 30, 2017


  3. Bipin Damania

    Bipin Damania Active Member


    I tried to add column VAT Tin Number & GST Number but not getting the same please check & reply.
     


  4. ebek

    ebek Member


    sir,
    problem is not filtering Notoptional voucher &Not showing voucher translation pairwise sales report.
    Filter : BWRFilter, NotIsoptional Voucher
    upload_2017-12-31_0-29-35.png
     

    Attached Files:

    • pwr.txt
      File size:
      15.4 KB
      Views:
      130


  5. Bipin Damania

    Bipin Damania Active Member


    Not getting. And also as per Image bottom three button is also not showing to me i.e.Ledger, Add Voucher & Contact
     


  6. Bipin Damania

    Bipin Damania Active Member


    Not getting. And also as per Image bottom three button is also not showing to me i.e.Ledger, Add Voucher & Contact
     


  7. RT Tripathi

    RT Tripathi New Member


    Partywise Report.txt
    Error T0044 description name duplicate
     


  8. Bipin Damania

    Bipin Damania Active Member


    I tried to add column VAT Tin Number & GST Number and also GST Tax Rate and GST HSN Code with Item Name but not getting the same.

    Please check & reply. I am waiting....
     



  9. Dear Sir
    Sorry for interrupting. Will you please check my one. I am not getting value from collection while selecting Auto Column.

    Thank You
     

    Attached Files:



  10. Hemanth

    Hemanth New Member


    You can try this TDL it is solved file for the Error T0044 description name duplicate
     

    Attached Files:



  11. ashish t

    ashish t New Member


    i want voucher no in this report can anyone help me...
     



  12. i want it to connect to Outstanding Report how to change the coding
    What to use Bill or Voucher
    where to find Receivable Bills
     


  13. Rajsrisrimal

    Rajsrisrimal Member


    sir,
    In this report can we check Sales return also ?
     


  14. Mukesh1001

    Mukesh1001 New Member


    ;===============================================================
    ;======================= F11 Feature ===========================
    ;===============================================================
    [#Part: CMP TallyShopFeatures Left]
    Add : Line : At End : CMP EnableBrokerLine

    [Line:CMP EnableBrokerLine]
    Space Bottom : 1.5 mms
    Field : Long Prompt,CMP EnableBrokerLine
    Local : Field : Long Prompt : Set as : "Enable Broker wise Report.?:"

    [Field:CMP EnableBrokerLine]
    Use : Logical Field
    Storage : EnableBroker
    Set as : If $$IsEmpty:$$Value then "No" else $$Value
    Sub Form: CMP BrokerNameReport: $$Value = "Yes"
    [Report: CMP BrokerNameReport]
    Form : CMP BrokerNameForm
    Object : Company
    [Form: CMP BrokerNameForm]
    Part : CMPBrokerDetails
    Background : White, Petal Pink
    [Field:CMPName Field]
    Use : Name Field
    Skip : Yes
    Align : Center
    Border : Thin Bottom

    [Part:CMPBrokerDetails]
    Part : CMP BrokerNamePart,CMP TransportPart,CMP LoadManPart
    Vertical : No
    Common Border : Yes
    [Part: CMP BrokerNamePart]
    Line : CMP BrokerNamePartTit,CMP BrokerName LineDetails
    Repeat : CMP BrokerName LineDetails: BrokerNameList
    BreakOn : $$IsEmpty:$BrokerNameList
    Height : 10
    Scroll : Vertical
    CommonBorder: Yes
    Space Left : 2 mms
    Space Right : 2 mms
    Border : Thin Right

    [Line:CMP BrokerNamePartTit]
    Field : CMPName Field
    Local : Field : CMPName Field : Set as : "Boker Name"
    [Line: CMP BrokerName LineDetails]
    Field : CMP BrokerNameList;,CMP TransportList,CMP LoadmanList;,CMP Broker CommissionField
    [Field: CMP BrokerNameList]
    Use : Name Field
    Storage : BrokerNameList
    Style : Small Bold

    [Part:CMP TransportPart]
    Line : CMP TransportPartTit,CMP TransportPart
    Repeat : CMP TransportPart: TransportList
    BreakOn : $$IsEmpty:$TransportList
    Height : 10
    Scroll : Vertical
    CommonBorder: Yes
    Space Left : 2 mms
    Space Right : 2 mms
    Border : Thin Right

    [Line:CMP TransportPartTit]
    Field : CMPName Field
    Local : Field : CMPName Field : Set as : "Transport Name"

    [Line:CMP TransportPart]
    Field : CMP TransportList

    [Field: CMP TransportList]
    Use : Name Field
    Storage : TransportList
    Style : Small Bold

    [Part:CMP LoadManPart]
    Line : CMP LoadmanListTit,CMP LoadmanList
    Repeat : CMP LoadmanList: LoadmanList
    BreakOn : $$IsEmpty:$LoadmanList
    Height : 15
    Scroll : Vertical
    CommonBorder: Yes
    Space Left : 2 mms
    Space Right : 2 mms

    [Line:CMP LoadmanListTit]
    Field : CMPName Field
    Local : Field : CMPName Field : Set as : "Loadman Name"

    [Line:CMP LoadmanList]
    Field : CMP LoadmanList

    [Field: CMP LoadmanList]
    Use : Name Field
    Storage : LoadmanList
    Style : Small Bold

    ;===============================================================
    ;======================= Add Fields ===========================
    ;===============================================================
    [#Part:DBLLINE Narration]
    Add : Line : Before : VCH NarrPrompt : VCHBrokerLine

    [Line:VCHBrokerLine]
    Invisible : NOT $EnableBroker:Company:##SVCurrentCompany OR NOT $$IsSales:##SVVoucherType
    Field : VCHBrokerNameTit,VCHBrokerName,VCHTransportTit,VCHTransport,VCHLoadManTit,VCHLoadMan
    [Field:VCHBrokerNameTit]
    Use : Meduim Prompt
    Set as : "Broker Name :"
    Skip : Yes

    [Field:VCHTransportTit]
    Use : VCHBrokerNameTit
    Set as : "Transport Name :"

    [Field:VCHLoadManTit]
    Use : VCHBrokerNameTit
    Set as : "Loadman Name :"

    [Field:VCHBrokerName]
    Use : Name Field
    Storage : BrokerName
    Table : BrokerNameColl,EndofList
    Show Table : Always
    Key : CreateBroker

    [Field:VCHTransport]
    Use : Name Field
    Storage : TransportName
    Table : TransportNameColl,EndofList
    Show Table : Always
    Key : CreateBroker

    [Field:VCHLoadMan]
    Use : Name Field
    Storage : LoadmanName
    Table : LoadmanNameColl,EndofList
    Show Table : Always
    Key : CreateBroker

    [Key:CreateBroker]
    Key : Alt + C
    Action : Alter : CMP BrokerNameReport

    ;;=========================================================
    ;;================= Broker wise Report ==================
    ;;=========================================================
    [#Menu: Gateway of Tally]
    Add : Key Item : After : @@locSalesRegister : "Party-wise Sales" : R : Display : BrokerReport
    ;Control : BrokerReport : $EnableBroker:Company:##SVCurrentCompany

    [Report:BrokerReport]
    Use : DSP Template
    Title : "Broker Report"
    Variable: SVFromDate, SVToDate
    Repeat : PARTYNAME1
    Form : BrokerReport
    Set : SVFromDate : $$MonthStart:##SVCurrentDate
    Set : SVToDate : $$MonthEnd:##SVCurrentDate
    Set : FilterBroker : ""
    Set : FilterTransport : ""
    Set : FilterLoadman : ""

    [Form:BrokerReport]
    Button : PrintButton, ExportButton
    Button : ExplodeFlag,ChangePeriod,BtnBroker
    Bottom Toolbar Buttons : EnterToEdit, BottomToolBarBtn8,BottomToolBarBtn9,BottomToolBarBtn10
    Part : BWRTitle,BWRPeriod,BWRFilter,BWRDetails
    Bottom Part :BWRTotals
    Width : 75% Page
    Space Left : 2 mms
    Space Right : 2 mms

    [Key: EnterToEdit]
    Key : Enter
    Title : $$LocaleString:"Explode"
    Type : BottomToolBarBtn2
    Action : Explode

    [Part:BWRTitle]
    Line : BWRTitle
    Horizontal Align : Center

    [Part:BWRPeriod]
    Line : BWRPeriod

    [Line:BWRTitle]
    Field : Simple Field
    Local : Field : Simple Field : Style : Large Bold
    Local : Field : Simple Field : Info : "Party-wise Sales"
    Local : Field : Simple Field : Border: Thin Bottom
    Local : Field : Simple Field : Align : Center

    [Line:BWRPeriod]
    Right Field : Name Field
    Left Field : Short Prompt,RPTBrokerFilter
    Local : Field : Name Field : Info : @@DSPDateStr
    Local : Field : Name Field : Width : 50
    Local : Field : Name Field : Align : Right
    Local : Field : Short Prompt : Set as: "Broker:"
    Local : Field : Short Prompt : Inactive: Not $EnableBroker:Company:##SVCurrentCompany
    [Part:BWRFilter]
    Line : BWRTranFilter,BWRLMFilter
    Invisible : Not $EnableBroker:Company:##SVCurrentCompany
    [Line:BWRTranFilter]
    Field : Short Prompt,RPTTransportFilter
    Space Top : 1 mms
    Local : Field : Default : Use : Simple Field
    Local : Field : Short Prompt : Set as : "Transport:"

    [Line:BWRLMFilter]
    Field : Short Prompt,RPTLoadManFilter
    Space Top : 1 mms
    Local : Field : Default : Use : Simple Field
    Local : Field : Short Prompt : Set as : "Loadman:"

    [Field:RPTBrokerFilter]
    Inactive : Not $EnableBroker:Company:##SVCurrentCompany
    Use : Simple Field
    Style : Normal Bold
    Set as : @VCHBrokerName
    Set Always : Yes
    VCHBrokerName : If $$IsEndOfList:##FilterBroker or ##FilterBroker="" Then "Show All" Else ##FilterBroker

    [Field:RPTTransportFilter]
    Use : RPTBrokerFilter
    Set as : @VCHTransport
    VCHTransport : if ##FilterTransport="" or $$IsEndOfList:##FilterTransport Then "Show All" Else ##FilterTransport

    [Field:RPTLoadManFilter]
    Use : RPTBrokerFilter
    Set as : @VCHLoadMan
    VCHLoadMan : if ##FilterLoadman="" or $$IsEndOfList:##FilterLoadman Then "Show All" Else ##FilterLoadman

    [Line:BWRHead]
    Use : BWRDetails
    Border : Column Titles
    Local : Field : Default : Type : String
    Local : Field : Default : Align : Center
    Local : Field : Default : Border : Thin Left
    Local : Field : Default : Style : Normal Bold
    Local : Field : SWSno : Set as : "Sno"
    Local : Field : SWSno : Border : Thin Left Right
    Local : Field : BWRPARTYNAME1 : Set as : "Party Name"
    Local : Field : BWRPARTYNAME1 : Align : Center
    Local : Field : BWRPARTYVATNo : Set as : "VAT No"
    Local : Field : BWRPARTYVATNo : Align : Center
    Local : Field : BWRPARTYGSTNo : Set as : "GST No"
    Local : Field : BWRPARTYGSTNo : Align : Center
    Local : Field : BWRActulQty : Set as : "Actual Qty"
    Local : Field : BWRActulQty : Align : Center
    Local : Field : BWRBilledQty : Set as : "Billed Qty"
    Local : Field : BWRBilledQty : Align : Center
    Local : Field : BWRAmount : Set as : "Amount"
    Local : Field : BWRAmount : Border : Thin Left Right
    Space Top : 1.5 mms
    Space Bottom: 1.5 mms

    [Part:BWRDetails]
    Line : BWRHead,BWRDetails
    Repeat : BWRDetails:BWRPartyWise
    Scroll : Vertical
    Total : BWRActulQty,BWRBilledQty,BWRAmount
    Common Border : Yes

    [Line:BWRDetails]
    Field : SWSno,BWRPARTYNAME1,BWRPARTYVATNo,BWRPARTYGSTNo
    Right Field : BWRActulQty,BWRBilledQty,BWRAmount
    Option : AlterOnEnter : $$IsVoucher
    Space Bottom: 0.5 mms
    Space Top : 0.5 mms
    Border : Thin Top
    Explode : BWRExplode : ($$KeyExplode OR ##ExplodeFlag)

    [Field:BWRDefault]
    Use : Name Field
    Style : Normal Bold

    [Field:SWSno]
    Use : BWRDefault
    Set as : $$Line
    Width : 1.5 cm
    Align : Center
    Border : Thin Left Right

    [Field:BWRPARTYNAME1]
    Use : BWRDefault
    Set as : $PARTYNAME1
    Width : 60
    Quick Search: Yes
    Space Left : 2 mms
    [Field:BWRPARTYVATNo]
    Use : BWRDefault
    Set as : $VATTinNumber ;;"VAT No" :eek:k
    ; Set as : $InvPartyTIN ;ok
    ; Set As : $LedCSTNo ;ok
    ; Set As : $OnlyAlias:Ledger:#EIConsignee ;on invoice -ok
    ; set as : $LedgerMobile:Ledger:#EIConsignee ;on invoice -ok
    Set As : $OnlyAlias:Ledger:$PartyLedgerName ;ok
    ; Set As : @@VCHPartyTNNo ; Tin No" ;ok
    ; Set As : @@VCHPartyCSTNo ;ok
    ; Set As : $InterStateSTNumber:Ledger:$PartyLedgerName ;ok
    ; Set As : $MailName:Ledger:$PartyLedgerName ;ok
    ; set as : $LedgerMobile:Ledger:$PartyLedgerName ;ok
    ; set as : $LedgerPhone:Ledger:$PartyLedgerName ;ok

    Width : 12
    Quick Search: Yes
    Space Left : 2 mms
    [Field:BWRPARTYGSTNo]
    Use : BWRDefault
    Set as : $PartyGSTIn ;;"GST No"
    Set As : $LedCSTNo

    Width : 15
    Quick Search: Yes
    Space Left : 2 mms
    [Field:BWRActulQty]
    Use : Qty Field
    Type : Number
    Set as : $TotActQty;VoucherTypeName
    Width : 16
    Space Left : 2 mms
    Border : Thin Left Right

    [Field:BWRBilledQty]
    Use : BWRActulQty
    Set as : $TotBillQty
    Width : 16
    Space Left : 2 mms
    Border : Thin Right

    [Field:BWRAmount]
    Use : BWRDefault
    Set as : $TotAmount
    Type : Amount
    Width : @@AmountWidth
    Format : "No Zero, Symbol," + ##ShowForex
    Align : Right
    Key : Calculator
    Max : @@MaxNumberWidth
    Width : 16
    Space Right : 2 mms
    Border : Thin Right
    Tooltip : "Amount Without TAX"

    [Part:BWRTotals]
    Line : BWRTotal

    [Line:BWRTotal]
    Border : Totals
    Use : BWRDetails
    Local : Field : Default : Type : String
    Local : Field : Default : Align : Right
    Local : Field : Default : Style : Large Bold
    Local : Field : Default : Border : Thin Left
    Local : Field : SWSno : Set as : ""
    Local : Field : BWRPARTYNAME1 : Set as : "Grand Total"
    Local : Field : BWRPARTYVATNo : Set as : ""
    Local : Field : BWRPARTYGSTNo : Set as : ""
    Local : Field : BWRActulQty : Set as : $$Total:BWRActulQty
    Local : Field : BWRBilledQty : Set as : $$Total:BWRBilledQty
    Local : Field : BWRAmount : Set as : $$Total:BWRAmount
    Local : Field : BWRAmount : Border : Thin Left Right
    Local : Field : BWRAmount : Align : Right
    [Part:BWRExplode]
    Line : BWRExplode
    Repeat : BWRExplode:BWRPartyExplode
    Border : Thin Bottom

    [Line:BWRExplode]
    Use : BWRDetails
    Delete : Border
    Local : Field : SWSno : Set as : ""
    Local : Field : Default : Style : Normal Italic
    Local : Field : BWRPARTYNAME1 : Set as : $ItemName
    Local : Field : BWRPARTYNAME1 : Align : Right
    Local : Field : BWRPARTYVATNo : Set as : "TAX Rate"
    Local : Field : BWRPARTYVATNo : Align : Right
    Local : Field : BWRPARTYGSTNo : Set as : "HSN Code"
    Local : Field : BWRPARTYGSTNo : Align : Right
    Local : Field : BWRActulQty : Type : Quantity
    Local : Field : BWRActulQty : Set as : $SubActQty
    Local : Field : BWRBilledQty : Type : Quantity
    Local : Field : BWRBilledQty : Set as : $SubBillQty
    Local : Field : BWRAmount : Set as : $SubAmount
    ;===============================================================
    ;======================= Add Filters ===========================
    ;===============================================================
    [Button:BtnBroker]
    Key : F5
    Action : Execute : BrokerReportWise
    Title : Broker Wise
    Inactive: Not $EnableBroker:Company:##SVCurrentCompany

    [Report:BrokerReportWise]
    Form : BrokerReportWise

    [Form:BrokerReportWise]
    Part : BrokerReportWise
    Space Left : 2 mms
    Space Right : 2 mms
    [Part:BrokerReportWise]
    Line : BrokerReportWise,FilterTransport,FilterLoadman
    [Line:BrokerReportWise]
    Field : Medium Prompt,BrokerReportWise
    Local : Field : Medium Prompt : Set as : "Select Broker Name:"
    Space Bottom : 2 mms

    [Field:BrokerReportWise]
    Table : BrokerNameColl,EndOfList
    ShowTable : Always
    Use : Name Field
    Width : 20
    Border : Thin Box
    Variable : FilterBroker
    Modifies : FilterBroker

    [Line:FilterTransport]
    Field : Medium Prompt,FilterTransport
    Local : Field : Medium Prompt : Set as : "Select Transport Name:"
    Space Bottom : 2 mms

    [Field:FilterTransport]
    Table : TransportNameColl,EndOfList
    ShowTable : Always
    Use : Name Field
    Width : 20
    Border : Thin Box
    Variable : FilterTransport
    Modifies : FilterTransport

    [Line:FilterLoadman]
    Field : Medium Prompt,FilterLoadman
    Local : Field : Medium Prompt : Set as : "Select Loadman Name:"
    Space Bottom : 2 mms

    [Field:FilterLoadman]
    Table : LoadmanNameColl,EndOfList
    ShowTable : Always
    Use : Name Field
    Width : 20
    Border : Thin Box
    Variable : FilterLoadman
    Modifies : FilterLoadman

    ;=============================================================
    ;================= System Functions =========================
    ;=============================================================

    [System:UDF]
    EnableBroker : Logical : 4566
    BrokerNameList : String : 4567
    TransportList : String : 4568
    LoadmanList : String : 4569
    BrokerName : String : 4570
    TransportName : String : 4571
    LoadmanName : String : 4572

    [System:Formula]
    BWRFilter : $BrokerName=@@BrokerWise AND $TransportName=@@TransportWise AND $LoadmanName=@@LoadmanWise
    BrokerWise : If $$IsEndOfList:##FilterBroker or ##FilterBroker="" Then $BrokerName Else ##FilterBroker
    TransportWise : If $$IsEndOfList:##FilterTransport or ##FilterTransport="" Then $TransportName Else ##FilterTransport
    LoadmanWise : If $$IsEndOfList:##FilterLoadman or ##FilterLoadman="" Then $LoadmanName Else ##FilterLoadman
    BWRExplodeFilter: $PARTYNAME1=#BWRPARTYNAME1
    MobilIteme : $LedgerMobile:Ledger:$PartyLedgerName ;ok
    VCHPartyTNNo : If @@IsIndianVATvch then $VATTINNumber:Ledger:$PartyLedgerName else $SalesTaxNumber:Ledger:$PartyLedgerName
    VCHPartyCSTNo : $InterStateSTNumber:Ledger:$PartyLedgerName
    VCHPartySTNo : $RegistrationNumber:Ledger:$PartyLedgerName
    [#Object:StockItem]
    AliasnameItem:$$Alias
    [#Object: Ledger]
    OnlyAlias : $$Alias

    [Collection: BWR Voucher]
    Type : Vouchers : VoucherType
    Child of : $$VchTypeSales
    Belongs to : Yes
    Fetch : Date,VoucherTypeName,PartyLedgerName,BasicPurchaseOrderNo,Amount,BrokerName,TransportName,LoadmanName
    Fetch : Ledger:VATTinNumber,Ledger:partyGSTIN
    Filter : NOTIsOptionalVoucher,BWRFilter

    [Collection:BWRPartyWise]
    Source Collection : BWR Voucher
    Walk : Inventory Entries
    By : PARTYNAME1 : $PartyLedgerName
    Aggr Compute: TotActQty : Sum : $ActualQty
    Aggr Compute: TotBillQty: Sum : $BilledQty
    Aggr Compute: TotAmount : Sum : $Amount
    ;=================================================
    Compute : PartyLedgerMobile : $LedgerMobile:Ledger:$...PartyLedgerName
    Compute : InvPartyTIN : If $$IsEmpty:$BasicBuyersSalesTaxNo Then @@VATPartyTinNumber Else $BasicBuyersSalesTaxNo
    Compute : LedCSTNo : If $$IsEmpty:$BuyersCSTNumber Then $InterStateSTNumber:Ledger:$PartyLedgerName Else $BuyersCSTNumber
    Compute : VATTINNumber : $VATTINNumber:Ledger:$PartyLedgerName
    Sort : Default : $PARTYNAME1
    Fetch : Date, VoucherTypeName, VoucherNumber, PartyLedgerName, LedgerName, IsInvoice, BasicBuyersSalesTaxNo, Reference, ECNonVATAmount, NonVATAmount, ECNonVatableAmount, VATAmount, ECVatAmount, TaxAmount, IsEmptyAssessableValue
    [Collection:BWRPartyExplode]
    Source Collection : BWR Voucher
    Walk : Inventory Entries
    By : PARTYNAME1 : $PartyLedgerName
    By : ItemName : $StockItemName
    Aggr Compute: SubActQty : Sum : $ActualQty
    Aggr Compute: SubBillQty: Sum : $BilledQty
    Aggr Compute: SubAmount : Sum : $Amount
    Filter : BWRExplodeFilter

    [Collection:BrokerNameColl]
    Type : BrokerNameList: Company
    Childof : ##SVCurrentCompany
    Format : $BrokerNameList,25
    Title : List of Brokers

    [Collection:TransportNameColl]
    Type : TransportList: Company
    Childof : ##SVCurrentCompany
    Format : $TransportList,25
    Title : List of Transports

    [Collection:LoadmanNameColl]
    Type : LoadmanList: Company
    Childof : ##SVCurrentCompany
    Format : $LoadmanList,25
    Title : List of Loadmans

    [Variable: PARTYNAME1]
    Type : String
    Repeat : ##DSPRepeatCollection
    [Variable:FilterBroker]
    Type : String

    [Variable:FilterTransport]
    Type : String

    [Variable:FilterLoadman]
    Type : String

    [System:Variables]
    FilterBroker : ""
    FilterTransport : ""
    FilterLoadman : ""
     


  15. Mukesh1001

    Mukesh1001 New Member



  16. Rajsrisrimal

    Rajsrisrimal Member


    Mukesh sir,
    In tally prime for Party wise sales report, Ctrl+R ( To remove an entry from a report) Not working in this, Any other button for
     


  17. Mukesh1001

    Mukesh1001 New Member


    [#Part: DB Columnar]
    Total : DBC ActulQty,DBC Less58779,DBC diffQty,DBC BilledQty,DBC QtyAmt,DBC Brokerege,DBC AmtTotal
    [#Part: CMP COLBasics]

    Add : Line :At beginning: COLREGWithLineSno1,COLREGWithActulQty,COLREGWithLess58779, +
    COLREGWithdiffQty, COLREGWithBillQty1, COLREGWithQtyAmt, +
    COLREGWithBrokerege, COLREGWithAmtTotal

    [Line: COLREGWithLineSno1]
    Fields : Medium Prompt, COLREGWithLineSno1
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show SN. ?"

    [Field: COLREGWithLineSno1]
    Use : Logical Field
    Modifies: COLREGWithSWSnoA
    [Line: COLREGWithActulQty]
    Fields : Medium Prompt, COLREGWithActulQty
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show ActulQty ?"
    [Field: COLREGWithActulQty]
    Use : Logical Field
    Modifies: COLREGWithActulQty
    [Line: COLREGWithLess58779]
    Fields : Medium Prompt, COLREGWithLess58779
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show Less58.779% ?"
    [Field: COLREGWithLess58779]
    Use : Logical Field
    Modifies: COLREGWithLess58779
    [Line: COLREGWithBillQty1]
    Fields : Medium Prompt, COLREGWithBillQty1
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show Billed Qty ?"
    [Field: COLREGWithBillQty1]
    Use : Logical Field
    Modifies: COLREGWithBillQty1
    [Line: COLREGWithdiffQty]
    Fields : Medium Prompt, COLREGWithdiffQty
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show diffQty ?"
    [Field: COLREGWithdiffQty]
    Use : Logical Field
    Modifies: COLREGWithdiffQty
    [Line: COLREGWithQtyAmt]
    Fields : Medium Prompt, COLREGWithQtyAmt
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show QtyAmt ?"
    [Field: COLREGWithQtyAmt]
    Use : Logical Field
    Modifies: COLREGWithQtyAmt
    [Line: COLREGWithBrokerege]
    Fields : Medium Prompt, COLREGWithBrokerege
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show Brokerege ?"
    [Field: COLREGWithBrokerege]
    Use : Logical Field
    Modifies: COLREGWithBrokerege
    [Line: COLREGWithAmtTotal]
    Fields : Medium Prompt, COLREGWithAmtTotal
    Local : Field : Medium Prompt : Info : $$LocaleString:"Show AmtTotal ?"
    Space Bottom : 1
    [Field: COLREGWithAmtTotal]
    Use : Logical Field
    Modifies: COLREGWithAmtTotal
    [System: Variable]
    COLREGWithSWSnoA : Yes
    COLREGWithActulQty : Yes
    COLREGWithLess58779 : Yes
    COLREGWithdiffQty : Yes
    COLREGWithBillQty1 : Yes
    COLREGWithQtyAmt : Yes
    COLREGWithBrokerege : Yes
    COLREGWithAmtTotal : Yes
    [Variable: COLREGWithSWSnoA]
    Type : Logical
    Persistent : Yes
    [Variable: COLREGWithActulQty]
    Type : Logical
    Persistent : Yes
    [Variable: COLREGWithLess58779]
    Type : Logical
    Persistent : Yes
    [Variable: COLREGWithBillQty1]
    Type : Logical
    Persistent : Yes
    [Variable: COLREGWithdiffQty]
    Type : Logical
    Persistent : Yes
    [Variable: COLREGWithQtyAmt]
    Type : Logical
    Persistent : Yes
    [Variable: COLREGWithBrokerege]
    Type : Logical
    Persistent : Yes
    [Variable: COLREGWithAmtTotal]
    Type : Logical
    Persistent : Yes
    ;==============================================================================================================
    [#Line: DSP ColVchTitle]
    Local : Field : Default : Border: Thin Left ; Top
    Local: Field: COLREGWithSWSnoA : Set as: $$LocaleString:"SN."
    Local: Field: DBC ActulQty : Set as: $$LocaleString:"Actual Qty"
    Local: Field: DBC Less58779 : Set as: $$LocaleString:"Less 58.779 %"
    Local: Field: DBC diffQty : Set as: $$LocaleString:"diff Qty"
    Local: Field: DBC BilledQty : Set as: $$LocaleString:"Billed Qty"
    Local: Field: DBC QtyAmt : Set as: $$LocaleString:"diffQty Amt"
    Local: Field: DBC Brokerege : Set as: $$LocaleString:"Brokerege"
    Local: Field: DBC AmtTotal : Set as: $$LocaleString:"Total Amt "
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    [#Line : DSP ColVchDetail]
    Add: Fields: Before: DBC Fixed : COLREGWithSWSnoA
    Add: Fields: Before: DBC Qty : DBC ActulQty,DBC Less58779,DBC diffQty,DBC BilledQty,DBC QtyAmt,DBC Brokerege,DBC AmtTotal
    Total: DBC ActulQty,DBC Less58779,DBC diffQty,DBC BilledQty,DBC QtyAmt,DBC Brokerege,DBC AmtTotal
    Border : Thin Top Bottom
    [Field:COLREGWithSWSnoA]
    Use : Number Field
    Set as : $$Line
    Width : 1 cm
    Align : Center
    Format : "No Zero"
    Invisible : NOT ##COLREGWithSWSnoA
    ;Border : Thin Left Right
    ;Background : Gree

    [Field:DBC ActulQty]
    Use : Qty Primary Field
    Set as : $$CollQtyTotal:InventoryEntries:$ActualQty
    Invisible : NOT ##COLREGWithActulQty
    Border : Thin Left
    Width : @@QtyWidth + @@UnitsWidth + 1
    ; Format : "NoSymbol, NoZero, ,Decimal:2" + ##ShowForex
    [Field : DBC Less58779]
    Use : Qty Primary Field
    Set as : $$CollQtyTotal:InventoryEntries:$DNS36
    Invisible : NOT ##COLREGWithLess58779
    Width : @@QtyWidth + @@UnitsWidth + 2
    [Field : DBC diffQty]
    Use : Qty Primary Field
    Set as :$$CollQtyTotal:InventoryEntries:$$Round:$DNSDeffSqyd:.0001
    Invisible : NOT ##COLREGWithdiffQty
    Background : @@SV_UNORANGE ;YELLOW
    Width : @@QtyWidth + @@UnitsWidth + 1
    [Field: DBC BilledQty]
    Use : Qty Primary Field
    Set as :$$CollQtyTotal:InventoryEntries:$$Round:$BilledQty:.0001
    Invisible : NOT ##COLREGWithBillQty1
    Background : YELLOW
    Width : @@QtyWidth + @@UnitsWidth + 1
    [Field : DBC QtyAmt]
    Use : Amount Field
    Set as : $$CollQtyTotal:InventoryEntries:$DNSDeffAmt
    Invisible : NOT ##COLREGWithQtyAmt
    Background : @@SV_AUDIT
    Format : "DrCr"
    [Field : DBC Brokerege]
    Use : Amount Field
    Set As : -$$Abs:($$CollAmtTotal:inventoryentries:mad:@DNSBrokerageCal)
    Style : Normal Bold
    Invisible : NOT ##COLREGWithBrokerege
    Width : @@AmountWidth
    Format : "DrCr"
    [Field:DBC AmtTotal]
    Use : Amount Field
    set As : ($$CollQtyTotal:InventoryEntries:$DNSDeffAmt + $$CollAmtTotal:inventoryentries:mad:@DNSBrokerageCal)
    Invisible : NOT ##COLREGWithAmtTotal
    Width : @@AmountWidth
    Background : red
    Format : "DrCr"
    [#Part: DBC QtyDetails]
    Local : Line : Default : Delete : Border
    Local: Field: Default : Style : Normal
    Local: Field: Default : Delete : Background
    Local:Field:COLREGWithSWSnoA : Set as: ""
    Local: Field: DBC ActulQty : Set as: $ActualQty ;$ActulQty
    Local: Field: DBC Less58779 : Set as: (($ActualQty)* 58.7791 /100)
    Local: Field: DBC diffQty : Set as: $DNSDeffSqyd
    Local: Field: DBC BilledQty : Set as: $BilledQty ;$BilledQty
    Local: Field: DBC QtyAmt : Set as: $DNSDeffAmt ;$DBCQtyAmt
    Local: Field: DBC Brokerege : Set as: -$$Abs:mad:@DNSBrokerageCal ;$DNSBrokerage ;@@DNSBrokeragecal ;
    Local: Field: DBC AmtTotal : Set as: if $$IsDr:$DNSDeffAmt OR $$IsEmpty:$DNSDeffAmt=$$AsAmount:0 then ($DNSDeffAmt) + ($$Abs:$DNSBrokerage)else ($$Abs:$DNSDeffAmt) - ($$Abs:$DNSBrokerage)
    Local : Field : COLREGWithSWSnoA : Delete : Border
    [#Line : DSP ColVchTotal]
    Add : Fields : Before : DBC Fixed : COLREGWithSWSnoA
    Add : Fields : Before : DBC Qty : DBC ActulQty,DBC Less58779,DBC diffQty,DBC BilledQty,DBC QtyAmt,DBC Brokerege,DBC AmtTotal
    Use : DSP ColVchDetail
    Space Top : if $$InPrintMode then 0.25 else 0
    Fixed : Yes
    Local : Field : Default : Inactive: No
    Local: Field: COLREGWithSWSnoA : Set as: ""
    Local: Field: DBC ActulQty : Set as: $$Total:DBCActulQty
    Local: Field: DBC Less58779 : Set as: $$Total:DBCLess58779
    Local: Field: DBC Less58779 : Background : Green
    Local: Field: DBC diffQty : Set as: $$Total:DBCdiffQty
    Local: Field: DBC BilledQty : Set as: $$Total:DBCBilledQty
    Local: Field: DBC QtyAmt : Set as: $$Total:DBCQtyAmt
    Local: Field: DBC Brokerege : Set as: $$Total:DBCBrokerege
    Local: Field: DBC AmtTotal : Set as: $$Total:DBCAmtTotal
    [#Collection : Columnar Filtered Vouchers of Company]
    Fetch :COLREGWithSWSnoA, COLREGWithActulQty, COLREGWithLess58779, COLREGWithdiffQty, COLREGWithQtyAmt, COLREGWithBrokerege, COLREGWithAmtTotal
    [#Collection: Columnar Vouchers of Ledgers]
    Fetch : InventoryEntries.*
    [#Collection: Columnar Vouchers of Company]
    Fetch : InventoryEntries.*
    Fetch : InventoryEntries.AddlAmount, InventoryEntries.DiffActualQty
    upload_2021-11-14_18-9-50.png
     


Share This Page