1. CLICK HERE TO JOIN WHATSAPP CHANNEL FOR TDL PROGRAMS

Print Qty in HSN Summary Table in Invoice Print

Discussion in 'Free Source Codes' started by vishal.jayswal09, Aug 16, 2020.

    
Page 1 of 2
  1. vishal.jayswal09

    vishal.jayswal09 Member


    Hello Team,

    Please help me how to Print Qty in HSN Summary Table in Invoice Print as per below format.


    upload_2020-8-16_20-21-19.png
     
    vishal.jayswal09, Aug 16, 2020
    #1


  2. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Seems you already have it.....as shown in the above image.
     
    Amit Kamdar, Aug 16, 2020
    #2


  3. vishal.jayswal09

    vishal.jayswal09 Member


    Hello Sir,

    No... I got reference which s already developed.
    So kindly suggest / Help for how to get this result.
     
    vishal.jayswal09, Aug 17, 2020
    #3


  4. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    You will have to add your QTY...title and value fields in the Print Format....of GST Analysis.

    Then either compute the value for the QTY or make a function to get the quantity.
     
    Amit Kamdar, Aug 17, 2020
    #4


  5. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Look up .... Part: VCH GST AnalysisDetails in Developer.

    You will find the lines here.... In the Lines, you have to add your fields.
     
    Amit Kamdar, Aug 17, 2020
    #5
    Jaydeep Shah likes this.


  6. vishal.jayswal09

    vishal.jayswal09 Member


    Hello Sir,

    Thank you ... but help me for create compute the value for the QTY or make a function to get the quantity.
    Please suggest..
     
    vishal.jayswal09, Aug 17, 2020
    #6


  7. Himanshu-2002

    Himanshu-2002 Active Member


    Share Your Code I will Try to help you
     
    Himanshu-2002, Aug 17, 2020
    #7


  8. vishal.jayswal09

    vishal.jayswal09 Member


    [#Line:VCHGSTInvPrintTitle1]
    Add : Field : After : VCHGSTInvPrint HSNCode : VCHGSTQ
    Local : Field : VCHGSTQ : Set as: "Qty "
    [#Line:VCHGSTInvPrintTitle2]

    Local : Field : VCHGSTQ : Set As : $$LocaleString:" "

    [#Line: GST VCHGSTInvPrintBody]

    Add : Field : After : VCHGSTInvPrint HSNCode : VCHGSTQ


    [Field : VCHGSTQ]

    Use : Number Field
    Format : "No Symbol"
    Set as : $BilledQty;$$Total:$$AsQty:$GSTStockItemQtyEx ;s$BilledQty
    Width : 5
    ;Border : THin Left


    [*Collection: GSTAnalysisPrintSummarySrc]

    Data Source : Variable: lvGSTAnalysisDetails
    Fetch : *.*
    Client Only : Yes
    Fetch: GSTStockItemQtyEx

    [*Collection: GSTAnalysisPrintSummary]

    Source Collection: GSTAnalysisPrintSummarySrc

    ComputeVar : GSTItemLedRate : String : $$Sprintf:"%s~%s~%s~%s~%s":$CGSTTaxate:$SGSTTaxate:$IGSTTaxate:$CessGSTTaxate:$CessGSTTaxRateQty
    ComputeVar : GSTItemValType : String : $$Sprintf:"%s~%s~%s~%s":$CGSTValType:$SGSTValType:$IGSTValType:$CessGSTValType

    Compute Var : CGSTValType : String : If $$IsEmpty:$CGSTValType Then $$SysName:OnValue Else $CGSTValType
    Compute Var : SGSTValType : String : If $$IsEmpty:$SGSTValType Then $$SysName:OnValue Else $SGSTValType
    Compute Var : IGSTValType : String : If $$IsEmpty:$IGSTValType Then $$SysName:OnValue Else $IGSTValType
    Compute Var : CessValType : String : If $$IsEmpty:$CessGSTValType Then $$SysName:OnValue Else $CessGSTValType

    Compute Var : vIsAnyValuationTypeOnQty : Logical : ##CGSTValType CONTAINS "Quantity" OR ##SGSTValType CONTAINS "Quantity" OR ##IGSTValType CONTAINS "Quantity" OR ##CessValType CONTAINS "Quantity"
    ;Aggr Compute : : $GSTStockItemQtyEx ;If $$IsEmpty:$GSTStockItemQtyEx Then $$InitValue:Quantity Else $GSTStockItemQtyEx
    By : GSTInvoice_ItemHSNCode : If $$IsEmpty:$GSTTransNature Then "" Else $GSTItemLedHSNCode
    By : GSTInvoice_ItemLedRate : If $$IsEmpty:$GSTTransNature Then "" Else ##GSTItemLedRate

    By : GSTInvoice_ItemCalcType : If ##vIsAnyValuationTypeOnQty Then ##GSTItemValType Else ""

    ; By : GSTInvoice_Qty : $GSTQty

    ; Compute : GSTInvoice_Qty :$GSTStockItemQty

    Compute : GSTInvoice_EntryLedgerName : $GSTLedgerName
    Compute : GSTInvoice_TransLedName : $GSTLedgerName
    Compute : GSTInvoice_TransNature : $GSTTransNature
    Compute : GSTInvoice_IsGSTTaxableTrn : $GSTTransNature
    Compute : GSTInvoice_StockItemNAme : $GSTStockItemName
    Compute : GSTInvoice_IsGSTLocalTransNat : $IsGSTLocalTransNat
    Compute : GSTInvoice_FirstTransNature : $GSTFirstTransNatureType

    Compute : GSTInvoice_CGSTClsfnRate : $CGSTTaxate
    Compute : GSTInvoice_SGSTClsfnRate : $SGSTTaxate
    Compute : GSTInvoice_IGSTClsfnRate : $IGSTTaxate
    Compute : GSTInvoice_CessGSTClsfnRate : $CessGSTTaxate
    Compute : GSTInvoice_CessGSTClsfnRateQty: $CessGSTTaxRateQty

    Compute : GSTInvoice_VchTransType : $GSTVchTransType
    Compute : GSTInvoice_VoucherTypeName : $IsGSTDelNoteVoucher
    Compute : GSTInvoice_GSTStockItemUOM : $GSTStockItemUOM




    Aggr Compute : GSTInvoice_GSTAssesableValue : Sum : $GSTAssesableAmount

    Aggr Compute : GSTInvoice_CGSTClsTaxAmt : SUM : $CGSTAmount
    Aggr Compute : GSTInvoice_SGSTClsTaxAmt : SUM : $SGSTAmount
    Aggr Compute : GSTInvoice_IGSTClsTaxAmt : SUM : $IGSTAmount
    Aggr Compute : GSTInvoice_CessGSTClsTaxAmt : SUM : $$NettAmount:$CessOnValGSTAmount:$CessOnQtyGSTAmount
    Aggr Compute : GSTInvoice_CessOnValAmt : SUM : $CessOnValGSTAmount
    Aggr Compute : GSTInvoice_CessOnQtyAmt : SUM : $CessOnQtyGSTAmount

    Aggr Compute : GSTInvoice_CGSTClsValType : SUM : $CGSTValType
    Aggr Compute : GSTInvoice_SGSTClsValType : SUM : $SGSTValType
    Aggr Compute : GSTInvoice_IGSTClsTValType : SUM : $IGSTValType
    Aggr Compute : GSTInvoice_CessGSTClsValType : SUM : $CessGSTValType

    Aggr Compute : BilledQty : Sum : $BilledQty ;GSTStockItemQtyEx

    Filter : GSTInvoice_IsNonEmpryGStNature
    Client Only : Yes

    Option : GSTAnalysisPrintSummary_RateWise : NOT @@InvGSTHSNWiseAnalysis
     
    vishal.jayswal09, Aug 17, 2020
    #8


  9. Himanshu-2002

    Himanshu-2002 Active Member


    Can You Give me a dummy data to test it?
     
    Himanshu-2002, Aug 17, 2020
    #9


  10. vishal.jayswal09

    vishal.jayswal09 Member


    Attached the sample data
     

    Attached Files:

    • TAL.rar
      File size:
      23.6 KB
      Views:
      43
    vishal.jayswal09, Aug 17, 2020
    #10


  11. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Study how $CGSTValType has been computed.........

    Similarly you will need to compute the Quantity.............
     
    Amit Kamdar, Aug 17, 2020
    #11
    Jaydeep Shah and tejeet like this.


  12. tejeet

    tejeet Member


    please check above code, qty against hsn code is coming zero, so please correct the code
     
    tejeet, Aug 17, 2020
    #12


  13. Himanshu-2002

    Himanshu-2002 Active Member


    Sorry, I didn't get time to check your code actually I am busy in 3 Projects But If I get time I will try to solve it for sure
     
    Himanshu-2002, Aug 17, 2020
    #13


  14. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Not getting the Values !!!!

    R&D and Search skills is equally important for learners and developers........ And I hope you guys improve the same........It will help immensely.


    Code:
    ; GST Analysis -- Qty Column Addition

; P A R E N T      R E F E R E N C E S
;        [!Form: Comprehensive Invoice]
;            [Part: VCH GST Analysis]
;            [Part: VCH GST AnalysisDetails]

[#Line : GST VCHGSTInvPrintBody]
    Add : Right Field : Before : VCHGSTInvPrint TaxValue : VCHGSTQty
    Local : Field     : VCHGSTQty : Set As     : $$Sprintf:"%s %s":$HSNwiseQTY:$HSNwiseQTYUQC

[#Line : VCHGSTInvPrintTitle1]
    Local : Field     : VCHGSTQty : Set As     : "Qty"

[#Line : VCHGSTInvPrintTitle2]
    Local : Field     : VCHGSTQty : Set As     : "Total"

[#Line : GST VCHGSTInvPrintTotal]  
    Local : Field     : VCHGSTQty : Set As     : "☼ ☼ ☼"
    Local : Field     : VCHGSTQty : Align        : Centre

[Field : VCHGSTQty]
    Use             : Name Field
    Width            : 6
    Align            : Centre

[#Collection : GSTAnalysisPrintSummary]
    Aggr Compute    : HSNwiseQTY    : Sum    : $GSTItemBilledQty
    Compute         : HSNwiseQTYUQC            : $GSTStockItemUOM
     
    Amit Kamdar, Aug 18, 2020
    #14
    gangstar, HVPatel and Jaydeep Shah like this.


  15. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Capture.PNG
     
    Amit Kamdar, Aug 18, 2020
    #15
    gangstar, Jaydeep Shah and tejeet like this.


  16. Himanshu-2002

    Himanshu-2002 Active Member


    Yes sir
     
    Himanshu-2002, Aug 18, 2020
    #16


  17. udaya

    udaya Active Member


    sir pls guide me....

    for Filed

    [Field:OTS AltBillQty]
    Use: Qty Secondary Field
    Set as: $QtyAlternate ;;; i think incorrect please .....
    Style:p9


    i cant get Alternate QTY in separate Column....
     
    udaya, Aug 18, 2020
    #17


  18. udaya

    udaya Active Member


    upload_2020-8-18_23-26-19.png
     
    udaya, Aug 18, 2020
    #18


  19. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    $ActualQty
     
    Amit Kamdar, Aug 18, 2020
    #19


  20. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    As you have your own report, you will need to compute the same in your collection.
     
    Amit Kamdar, Aug 18, 2020
    #20


  21. udaya

    udaya Active Member


    Amit Sir..... Thanks LOT.... I got it Perfectly.
     
    udaya, Aug 19, 2020
    #21


  22. udaya

    udaya Active Member


    upload_2020-8-19_6-21-34.png
     
    udaya, Aug 19, 2020
    #22


  23. udaya

    udaya Active Member


    Sir Please give me solution for SubTotal...


    [Field: EI ValueSubTotal1]
    Use : Amount Forex Field
    Set as : $$SignedAmount:$Amount
     
    udaya, Aug 19, 2020
    #23


  24. tejeet

    tejeet Member


    Dear Amit sir,
    can you add total hsn qty in gst analysis instead of blank in your above code - if all items in invoice has same unit measure than - total nos ( eg 20 nos ) or if all items has different unit of measure than only total qty ( eg 20 ) ( units of measure are nos , kgs, liters, packet ) .

    sir if possible please update the your above codes
     
    tejeet, Aug 19, 2020
    #24


  25. Amit Kamdar

    Amit Kamdar Administrator Staff Member


    Dear Udaya,

    Please open a new thread and post your queries, because they are not linked in any way to the THEME of this thread.

    In future if other members have a same query, no one would know that there is another query within a query.

    So in interest of the forum and proper search and to help other members, please open a new THREAD based on your topic. I will answer once you do that.

    Thanks for your cooperation and understanding.
     
    Amit Kamdar, Aug 19, 2020
    #25


Page 1 of 2

Share This Page