To display Outstanding of all Customer Bill wise in One Report

;; The sample code gives report showing All the Party Leger name with its Bill wise outstanding in One report - Zero balance filter given


[Color : MYColor]
RGB : 180,180,180

[System : Formula]
OnlyCplParty: $$IsBelongsTo:$$GroupSundryDebtors AND Not $$IsEmpty:$ClosingBalance

[#Menu : Gateway Of Tally]
Add : Item : Before : ~Quit : CP~L Reports : Menu : CPL Reports
[Menu : CplReports]

Item : CPL Bill Breakup : Display : CPL BillWise Report

[Report : CPL BillWise Report]

Form : MyTdl
Family : "Outstandings"

List Name : "Bill-wise Details"
Variables : SV CurrentCompany, SVFromDate, SVToDate, SVSortMethod, LedgerName, SVBudget, SVVariance
Variables : ExplodeFlag, IsForexReport
Variable : DSPShowMonthly, DSPHasMultiLevel
Variable : ShowDaysByBillDate
Variable : ShowBillRange, IsBillWiseReport, IsLedgerReport, IsCCReport, IsVchTypeReport
Variable : DSPNotScaleable, DSPHasColumnTotal, DSPAgeByDueDate
Variable : AgeFrom, AgeTo, ShowReminders, ShowForex
Variable : IsMultiPage, InNewPages, ShowBillType, IsGrpBillReport
Repeat : AgeFrom, AgeTo


Set : SV Sort Method : @@Default
Set : DSPShowMonthly : No
Set : ShowDaysByBillDate: No
Set : IsBillWiseReport : Yes
Set : IsLedgerReport : Yes
Set : IsGrpBillReport : No
Set : DSPHasMultiLevel : No
Set : DSPNotScaleable : Yes
Set : DSPHasColumnTotal : No
Set : IsMultiPage : No
Set : SVBudget : ""

Set : SV From Date : $$MonthStart:##SVCurrentDate
Set : SV To Date : $$MonthEnd:##SVCurrentDate

Export : Yes



[Form : MyTdl]

Use : DSP Template
Width : 100% Page
Height : 100% Page
BackGround : Light Sea Green
Parts : Subbu Title, Subbu Body ;;;,SubbuTotal
Button : Print Button,AgeWiseAnalysis


[Part : Subbu Title]

Line : subbu Title

[Border : Subbu Title Border]

Top : Thin
Bottom : Thin

[Line : Subbu Title]

Border : Subbu Title Border
Fields : Subbu Title
Right Fields : Subbu DrAmount Title, Subbu CrAmount Title

[Field : Subbu Title]

Use : Name Field
Set as : "Particulars"
FullWidth : Yes
Style : Large
Border : Thin Bottom


[Field : Subbu DrAmount Title]
Width : @@AmountWidth
Set as : "Debit"
Style : Large
Border : Thin Bottom
Align: Right

[Field : Subbu CrAmount Title]

Use : Subbu DrAmount Title
Set as : "Credit"
Style : Large
Border : Thin Bottom



[Part : Subbu Body]

Line : Subbu Body Detail ;;,Subbu
Repeat : Subbu Body Detail : Ledger
Scroll : Vertical
Local : Collection : Ledger : Filter : OnlyCplParty

[Line : Subbu Body Detail]
Left Fields : MyLedName
Right Fields : MyDrAmount , MyCrAmount
Explode : MyExplodPart : ($$KeyExplode OR ##ExplodeFlag)



[!Part : MyExplodPart]
Lines: JlLedger Bills Title, JlLedger Bills, Jl OnAccount Bills, ZJlEmptyLine
Repeat: JlLedger Bills : Ledger Bills
Scroll: Vertical
Vertical: Yes



[Line : ZJlEmptyLine]
Fields : Info Field
Local : Field : Info Field : Info : " "

[Line : JlLedger Bills Title]
Fields: JLBill DateTitle, JlBillNoTitle, JLBill AmountTitle, JlBill CreditPeriodTitle

[Field : JLBill DateTitle]
Use: Short Name Field
Set as: "Bill Date"
Style: Small
Width: 15
Align: Right

[Field : JLBillNoTitle]
Use: Short Name Field
Set as: "Bill Number"
Style: Small
Width: 14.5
Align: Right

[Field: JLBill AmountTitle]
Use: Short Name Field
Set as: "Pending Amount"
Style: Small
Width: 15


[Field : JLBill CreditPeriodTitle]
Use: Short Name Field
Set as: "Credit Period"
Style: Small
Width: 15
Align: Centre
[Line : Jl OnAccount Bills]
Empty: $$IsEmpty:$OnAccountValue:Ledger:#LedgerName
Fields: JLBill Date, JL OnAccount Bills Title, JL OnAccount Amount
Local: Field : JLBill Date : Set as : " "

[Field : Jl OnAccount Bills Title]
Use: Short Name Field
Style: Small Italic
Width: 14
Align: Right
Set as: "On Account "
Invisible: $$IsEmpty:$OnAccountValue:Ledger:#LedgerName

[Field : Jl OnAccount Amount]
Use: Amount Field
Set as: $OnAccountValue:Ledger:#LedgerName
Style : Small Italic
Width : 15
Format : "DrCr,NoZero," + ##ShowForex
Invisible: $$IsEmpty:$OnAccountValue:Ledger:#LedgerName

[Line : JlLedger Bills]
Fields: JLBill Date, JlBillNo, JLBill Amount, JlBill CreditPeriod

[Field : JLBill Date]
Use: UniDateField
Set as: $BillDate
Style: Small Italic
Width: 14

[Field : JLBillNo]
Use: Short Name Field
Set as: $Name
Style: Small Italic
Width: 14
Align: Right

[Field: JLBill Amount]
Use : AmountField
Type : Amount
Set as : $FinalBalance
Style : Small Italic
Width : 15
Format : "DrCr,NoZero," + ##ShowForex

[Field : JLBill CreditPeriod]
Use : UniDateField
Set as : If $$IsEmpty:$BillCreditPeriod then $BillDate else$BillCreditPeriod
Style : Small Italic
Width : 15

[Field : MyLedName]
Set As: $Name
Variable: LedgerName
Modifies: ledgerName
Style: Large
FullWidth: Yes
Invisible: $$IsEmpty:$ClosingBalance
Color: Blue
Background: MyColor

[Field : MyCrAmount]
Type: Amount
Width: @@AmountWidth
Align: Right
Border: Thin Bottom: $$IsExploded
Set as: If Not $$Isdr:$ClosingBalance Then $ClosingBalance Else0
Invisible: $$IsEmpty:$ClosingBalance
[Field : MyDrAmount]
Use: MyCrAmount
Set as: If $$IsDr:$ClosingBalance Then $ClosingBalance Else 0
Invisible: $$IsEmpty:$ClosingBalance

 

Hi,

I am getting an error message as follows, please correct it and repost. Thanks in Advance.

Cannot Understand
Bad Formula!
'If Not $$Isdr:$ClosingBalance Then $ClosingBalance Else0'

 

Pls insert a space between else and 0

u can see an additional option before Quit in Gateway of Tally "CPL Reports"

 

Hi
Nirav Merchant,


Thanks for such a fast response

 

In tally Developer 9 - in Help there are some sample code available for Invoice Customization u can check and learn - will help u a lot

 

I think we will get the same report by default:
Disp ->Acc books -> Group Summ -> (select Sundry Debtors)

 

what do to if i want a new column for interest calculated on bills.
and to get a print out of same report?

 

nice

 

Sir,

 

Sir, How can i get particular Sales VoucherType (Local Sales) outstanding. Please tell me sir

 

Dear sir,
is is possible to filter vouchers based on voucher type please suggess

 

yes, use functions like
$$IsContra:$VoucherTypeName

result will be either yes or no

 

HI Kamal,

Can u try this collection..

[Collection: MyVouchers]

Type: Vouchers : VoucherType
Childof : $$VchTypeSales ;;------ here you have give which voucher type u need to filter...
BelongsTo: Yes

 

Nirav sir
Bottom line Total field not reflect me

Please Help me

[Field : Subbu DrAmount Total]

Use : Amount Field
Set as : $MyTotal;MyDrAmount
Width : @@AmountWidth
Style : Large
;Border : Thin Bottom
Align : Right
Format : "DrCr,NoZero," + ##ShowForex