1. CLICK HERE TO JOIN WHATSAPP CHANNEL FOR TDL PROGRAMS

Sales Invoice & Gate Pass In Single Print

Discussion in 'Free Source Codes' started by D Lokesh, May 10, 2015.

    
  1. D Lokesh

    D Lokesh Member


    Hi

    ;;---------------------- Code

    ;;------- Sales & Gate Pass

    [#Form : Sales Color]

    Delete : Print : Printed Invoice
    Print : Sales GatePass

    [Report : Sales GatePass]

    Form : Sales GatePass
    Object : Voucher

    [Form : Sales GatePass]

    Part : Sales GatePass
    Width : 97% Page

    Horizontal Align : Center
    Space Left : 2
    Space Bottom : 2
    Space Top : 3
    Space Right : 2

    [Part : Sales GatePass]

    Parts : Sales Part, DummyPart, GetPass Part
    Vertical : No

    [Part : DummyPart]

    Line : DummyPart
    Width : 4% Page

    [Line : DummyPart]

    Field : Simple Field

    [Part : Sales Part]

    Parts : Sales PartT, Sales PartB
    Vertical : Yes
    Width : 70% Page

    [Part : Sales PartT]

    Line : Sales PartT

    [Line : Sales PartT]

    Field : Sales PartT
    Space Bottom : .5

    [Field : Sales PartT]

    Set as : "TAX - INVOICE"
    Align : Center
    Style : Normal Bold
    Width : 70% Page

    [Part : Sales PartB]

    Parts : Sal Top, Sal Body
    Bottom Part : Sal Bot
    Vertical : Yes
    Width : 70% Page
    Border : Thin Box

    [Part : Sal Top]

    Part : Sal TIN, Sal Form, Sal Buyer, Sal InvTit
    Vertical : Yes

    [Part : Sal TIN]

    Part : Sal TINNo, Sal FORMM
    Right Part: Sal Off
    Vertical : No
    Width : 70% Page

    [Part : Sal TINNo]

    Line : Sal TINNo, Sal AGL
    Width : 30% Page

    [Line : Sal TINNo]

    Field : Short Prompt, Sal TINNo
    Local : Field : Short Prompt : Info : "TIN"

    [Field : Sal TINNo]

    Set as : $VatTINNumber:Company:##SVCurrentCompany
    Style : Normal Bold

    [Line : Sal AGL]

    Field : Short Prompt, Sal AGL
    Local : Field : Short Prompt : Info : "AGL. No"

    [Field : Sal AGL]

    Set as : "VSP/38/ADA/FR/2012/1959"
    Style : Normal Bold

    [Part : Sal FORMM]

    Line : Sal FORMM

    [Line : Sal FORMM]

    Field : Sal FORMM

    [Field : Sal FORMM]

    Set as : "FORM - M"
    Width : 10% Page
    Style : Large Bold
    Align : Center

    [Part : Sal Off]

    Line : Sal Off
    ;Width : 30% Page

    [Line : Sal Off]

    Field : Sal Off

    [Field : Sal Off]

    Set as : "Off." + $PhoneNumber:Company:##SVCurrentCompany
    Style : Normal Bold

    [Part : Sal Form]

    Line : Sal Form

    [Line : Sal Form]

    Field : Sal Form
    Space Top : .2
    Space Bottom: .3

    [Field : Sal Form]

    Set as : "Form for Cash/Credit Memorandum to be Issued by the dealer, Fertilizer Control Order 1985"
    ; Line : 0
    Style : Small

    [Part : Sal Buyer]

    Part : Sal Cmp
    Right Part : Sal Buy
    Vertical : No
    Width : 70% Page
    Border : Thin Top

    [Part : Sal Cmp]

    Line : Sal CmpNm, Sal CmpAdd
    Width : 40% Page

    [Line : Sal CmpNm]

    Field : Sal CmpNm
    Space Top : 1

    [Field : Sal CmpNm]

    Set as : "M/s. Dasari Bulli Venkataraju"
    Style : SalBigFont
    Align : Center
    Width : 40% Page

    [Style : SalBigFont]

    Font : "Arial"
    Height : 14
    Bold : Yes

    [Line : Sal CmpAdd]

    Field : Sal CmpAdd
    Space Top : .5

    [Field : Sal CmpAdd]

    Set as : "PAYAKARAOPETA"
    Style : Large Bold
    Align : Center
    Width : 40% Page

    [Part : Sal Buy]

    Line : Sal InvNo, Sal InvDt, Sal Name, Sal Vil
    Repeat : Sal Vil : BasicBuyerAddress
    Border : Thin Left
    Local : Line : Default : Space Bottom : 1
    Width : 30% Page

    [Line : Sal InvNo]

    Field : Short Prompt, Sal InvNo
    Local : Field : Short Prompt : Info : "No"

    [Field : Sal InvNo]

    Set as : $VoucherNumber

    [Line : Sal InvDt]

    Field : Short Prompt, Sal InvDt
    Local : Field : Short Prompt : Info : "Date"

    [Field : Sal InvDt]

    Set as : $Date

    [Line : Sal Name]

    Field : Short Prompt, Sal Name
    Local : Field : Short Prompt : Info : "Name"

    [Field : Sal Name]

    Set as : @@ConsigneeName
    Align : Left
    Border : Thin Bottom

    [Line : Sal Vil]

    Field : Short Prompt, Sal Vil
    Local : Field : Short Prompt : Info : "Village"

    [Field : Sal Vil]

    Set as : $BasicBuyerAddress
    Align : Left
    Border : Thin Bottom

    [Part : Sal InvTit]

    Line : Sal InvTit

    [Line : Sal InvTit]

    Use : Sal InvDesc
    Border : Column Titles
    Local : Field : Sal InvQty : Info : "No.of Bags"
    Local : Field : Sal InvItem : Info : "Name of the Product"
    Local : Field : Sal InvBatNo : Info : "Batch No."
    Local : Field : Sal InvWgt : Info : "Weight Per Bag"
    Local : Field : Sal InvTax : Info : "Rate Per Bag Incl. All Taxes"
    Local : Field : Sal InvAmt : Info : "Amount"

    Local : Field : Default : Align : Center
    Local : Field : Default : Style : Normal Bold
    Local : Field : Default : Line : 0

    [Part : Sal Body]

    Line : Sal InvDesc
    Repeat : Sal InvDesc : Inventory Entries
    Scroll : Vertical
    Border : Thin Left Right
    Common Border: Yes
    Float : No
    Total : Sal InvQty, Sal InvAmt

    [Line : Sal InvDesc]

    Field : Sal InvQty, Sal InvItem, Sal InvBatNo, Sal InvWgt, Sal InvTax, Sal InvAmt
    Local : Field : Default : Style : Normal

    [Field : Sal InvQty]

    Use : Qty Primary Field
    Set as : $BilledQty
    Border : Thin Right
    Width : 10% Page
    Align : Right

    [Field : Sal InvItem]

    Use : Name Field
    Set as : $StockItemName
    Border : Thin Right
    Width : 20% Page

    [Field : Sal InvBatNo]

    Set as : $BatchName
    Width : 10% Page
    Border : Thin Right
    Align : Right

    [Field : Sal InvWgt]

    Set as : ""
    Width : 10% Page
    Border : Thin Right
    Align : Right

    [Field : Sal InvTax]

    Set as : $Rate
    Width : 10% Page
    Border : Thin Right
    Align : Right

    [Field : Sal InvAmt]

    Use : Amount Field
    Set as : $Amount
    Width : 10% Page
    Align : Right

    [Part : Sal Bot]

    Line : Sal Total, Sal Notes, Sal BuySign
    Border : Thin Top

    [Line : Sal Total]

    Use : Sal InvDesc
    Border : Totals
    Local : Field : Sal InvQty : Set as: $$Total:SalInvQty
    Local : Field : Sal InvItem : Info : ""
    Local : Field : Sal InvBatNo : Info : ""
    Local : Field : Sal InvWgt : Info : ""
    Local : Field : Sal InvTax : Info : ""
    Local : Field : Sal InvAmt : Set as: $$Total:SalInvAmt
    Local : Field : Default : Style : Normal Bold

    [Line : Sal Notes]

    Field : Short Prompt, Sal Notes
    Local : Field : Short Prompt : Info : "Notes"
    Space Top : .5

    [Field : Sal Notes]

    Set as : @L1 + @L2
    L1 : "1) Subject to Yellamanchili Jurisidiction. of intrest will be charged at 24% per "
    L2 : "annum if payment is not received per the week"
    Line : 0
    Full Width : Yes

    [Line : Sal BuySign]

    Field : Sal BuySign
    Right Field : Sal For
    Space Top : 1.5

    [Field : Sal BuySign]

    Set as : "Buyer Signature"
    Style : Normal Bold Italic
    Align : Left

    [Field : Sal For]

    Set as : "For " + @@CmpMailName
    Style : Normal Bold Italic
    Align : Right

    ;;------ Gate Pass

    [Part : GetPass Part]

    Part : GetPass Top, GetPass Body
    Bottom Part : GetPass Bot
    Vertical : Yes
    Width : 25% Page
    Border : Thin Box

    [Part : GetPass Top]

    Line : GetPass Dt, GetPass Tit, GetPass InNo, GetPass CmpNm, GetPass CmpAdd, GetPass InvTit

    [Line : GetPass Dt]

    Field : GetPass Dt
    Space Top : .5
    Space Bottom: .5

    [Field : GetPass Dt]

    Set as : "Date " + $$String:$Date
    Align : Center
    Width : 25% Page
    Full Width : Yes

    [Line : GetPass Tit]

    Field : GetPass Tit
    Space Bottom: .1

    [Field : GetPass Tit]

    Set as : "GATE - PASS"
    Style : Large Bold Italic
    Align : Center
    Full Width : Yes

    [Line : GetPass InNo]

    Field : GetPass InNo
    Space Bottom: .5

    [Field : GetPass InNo]

    Set as : "NO : " + $$String:$VoucherNumber
    Align : Center
    Width : 25% Page
    Full Width : Yes

    [Line : GetPass CmpNm]

    Field : GetPass CmpNm
    Space Bottom: .5

    [Field : GetPass CmpNm]

    Set as : "M/s. Dasari Bulli Venkataraju"
    Style : Large Bold
    Align : Center
    Full Width : Yes

    [Line : GetPass CmpAdd]

    Field : GetPass CmpAdd
    Space Bottom: .5

    [Field : GetPass CmpAdd]

    Set as : "PAYAKARAOPETA"
    Style : Normal Bold
    Align : Center
    Full Width : Yes

    [Line : GetPass InvTit]

    Field : GetPass Bags, GetPass Item
    Border : Column Titles
    Local : Field : GetPass Bags : Info : "Bags"
    Local : Field : GetPass Item : Info : "Particulars"

    Local : Field : Default : Align : Center
    Local : Field : Default : Style : Normal Bold

    [Part : GetPass Body]

    Line : GetPass Desc
    Repeat : GetPass Desc : Inventory Entries
    Scroll : Vertical
    Border : Thin Left Right
    Common Border: Yes
    Float : No

    [Line : GetPass Desc]

    Field : GetPass Bags, GetPass Item
    Space Bottom: .2

    [Field : GetPass Bags]

    Use : Qty Primary Field
    Set as : $BilledQty
    Border : Thin Right
    Width : 10% Page

    [Field : GetPass Item]

    Use : Name Field
    Set as : $StockItemName
    Width : 15% Page

    [Part : GetPass Bot]

    Line : GetPass Bot
    Border : Thin Top

    [Line : GetPass Bot]

    Field : GetPass Bot
    Space Top : 3

    [Field : GetPass Bot]

    Set as : "Signature"
    Style : Normal Bold
    Align : Right
    Full Width : Yes
    Width : 25% Page
     
    D Lokesh, May 10, 2015
    #1


  2. ANKUR

    ANKUR New Member


    PLEASE MAIL TDL OF INVOICE + GATE PASS
     
    ANKUR, Sep 15, 2015
    #2


  3. Praveen Davis

    Praveen Davis Member


    I have two different tdl; one for invoice and one for packing slip.

    How can I print invoice first and below loading slip in continuous stationary.
     
    Praveen Davis, Sep 17, 2015
    #3


Share This Page